fosdem-schedule.pro

   1 # fosdem-schedule.pro
   2
   3 QMAKEVERSION = $$[QMAKE_VERSION]
   4 ISQT4 = $$find(QMAKEVERSION, ^[2-9])
   5 isEmpty( ISQT4 ) {
   6 error("Use the qmake include with Qt4.4 or greater, on Debian that is
   7 qmake-qt4");
   8 }
   9
  10 TEMPLATE = subdirs
  11 SUBDIRS = src
  12
  13 VERSION = 0.5.0
  14
  15 QMAKE_EXTRA_TARGETS += tarball icon changelog release
  16
  17 changelog.target = ChangeLog
  18 changelog.commands = \
  19         svn up && svn2cl --group-by-day --reparagraph
  20 changelog.CONFIG = phony
  21
  22 icon.target = data/$${TARGET}.png
  23 icon.commands = convert data/$${TARGET}.svg data/$${TARGET}.png
  24 icon.depends = data/$${TARGET}.svg
  25
  26 release.depends = tarball
  27
  28 tarball.target = $${TARGET}-$${VERSION}.tar.gz
  29 tarball.commands = \
  30         $(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
  31         $(MKDIR) $${TARGET}-$${VERSION} ; \
  32         $(COPY_DIR) --parents * $${TARGET}-$${VERSION}/ ; \
  33         tar -cz --exclude=.svn -f $$tarball.target $${TARGET}-$${VERSION} ; \
  34         $(DEL_FILE) -r $${TARGET}-$${VERSION}
  35 tarball.depends = changelog icon