Removed dbus dependency on non-maemo platforms.
[toast/confclerk.git] / src / app / app.pro
1 include(../global.pri)
2 TEMPLATE = app
3 TARGET = fosdem-schedule
4 DESTDIR = ../bin
5 QT += sql xml network 
6 CONFIG(maemo5) {
7     QT += maemo5 dbus
8 }
9
10 # module dependencies
11 LIBS += -L$$DESTDIR -lgui -lmvc -lsql
12 INCLUDEPATH += ../gui ../sql ../mvc ../orm
13 DEPENDPATH += . ../gui
14 TARGETDEPS += $$DESTDIR/libmvc.a $$DESTDIR/libgui.a $$DESTDIR/libsql.a
15 maemo {
16     LIBS += -L$$DESTDIR -lqalarm -lalarm
17     INCLUDEPATH += ../alarm
18     DEPENDPATH +=  ../alarm
19     TARGETDEPS += $$DESTDIR/libqalarm.a
20     HEADERS += alarmdbus.h \
21         alarmdbusadaptorp.h
22     SOURCES += alarmdbus.cpp \
23         alarmdbusadaptor.cpp
24 }
25
26 HEADERS += appsettings.h \
27         application.h
28
29 SOURCES += main.cpp \
30            application.cpp \
31            appsettings.cpp
32
33 RESOURCES += ../icons.qrc \
34              ../maps.qrc
35
36 # qmake cannot work properly if the resource file does not exist already
37 system(rm -f ../fosdem.sqlite && sqlite3 ../fosdem.sqlite <../fosdem.sql) {
38  RESOURCES += ../db.qrc
39 } else {
40  error(sqlite3 failed)
41 }
42
43 db.target = ../fosdem.sqlite
44 db.depends = ../fosdem.sql
45 db.commands = rm -f $$db.target && sqlite3 $$db.target <$$db.depends
46 QMAKE_EXTRA_TARGETS += db
47
48 # instalation related
49
50 PREFIX = /usr/bin
51 INSTALLS = target
52 target.path = $$PREFIX
53