Add release and changelog targets to project file.
[toast/confclerk.git] / fosdem-schedule.pro
1 # fosdem-schedule.pro
2
3 QMAKEVERSION = $$[QMAKE_VERSION]
4 ISQT4 = $$find(QMAKEVERSION, ^[2-9])
5 isEmpty( ISQT4 ) {
6 error("Use the qmake include with Qt4.4 or greater, on Debian that is
7 qmake-qt4");
8 }
9
10 TEMPLATE = subdirs
11 SUBDIRS = src
12
13 VERSION = 0.5.0
14
15 QMAKE_EXTRA_TARGETS += tarball changelog release
16 QMAKE_DISTCLEAN += ChangeLog
17
18 changelog.target = ChangeLog
19 changelog.commands = \
20         svn up && svn2cl --group-by-day --reparagraph
21 changelog.CONFIG = phony
22
23 release.depends = tarball
24
25 tarball.target = $${TARGET}-$${VERSION}.tar.gz
26 tarball.commands = \
27         $(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
28         $(MKDIR) $${TARGET}-$${VERSION} ; \
29         $(COPY_DIR) --parents * $${TARGET}-$${VERSION}/ ; \
30         tar -cz --exclude=.svn -f $$tarball.target $${TARGET}-$${VERSION} ; \
31         $(DEL_FILE) -r $${TARGET}-$${VERSION}
32 tarball.depends = changelog