src/gui/gui.pro

   1 include(../global.pri)
   2 TEMPLATE = lib
   3 TARGET = gui
   4 DESTDIR = ../bin
   5 CONFIG += static
   6 QT += sql \
   7     xml \
   8     network
   9 QMAKE_CLEAN += ../bin/libgui.a
  10
  11 # module dependencies
  12 LIBS += -L$$DESTDIR \
  13     -lmvc \
  14     -lorm \
  15     -lsql
  16 INCLUDEPATH += ../orm \
  17     ../mvc \
  18     ../sql \
  19     ../app
  20 DEPENDPATH += . \
  21     ../orm \
  22     ../mvc \
  23     ../sql
  24 POST_TARGETDEPS += $$DESTDIR/liborm.a \
  25     $$DESTDIR/libmvc.a \
  26     $$DESTDIR/libsql.a
  27 maemo {
  28     LIBS += -L$$DESTDIR \
  29         -lqalarm
  30     INCLUDEPATH += ../alarm
  31     DEPENDPATH += ../alarm
  32     POST_TARGETDEPS += $$DESTDIR/libqalarm.a
  33 }
  34
  35 # A shamelessly long list of sources, headers and forms.
  36 # Please note that resources MUST be added to the app module
  37 # (which means they need to be added to the test module as well,
  38 # but I am sure you can live with that for the time being).
  39
  40 FORMS += searchhead.ui \
  41     mainwindow.ui \
  42     daynavigatorwidget.ui \
  43     about.ui \
  44     eventdialog.ui \
  45     conflictsdialog.ui \
  46     tabcontainer.ui \
  47     settingsdialog.ui \
  48     conferenceeditor.ui \
  49     urlinputdialog.ui
  50
  51 HEADERS += roomstabcontainer.h \
  52     trackstabcontainer.h \
  53     favtabcontainer.h \
  54     searchtabcontainer.h \
  55     searchhead.h \
  56     dayviewtabcontainer.h \
  57     conflictdialogcontainer.h \
  58     conflictsdialog.h \
  59     mainwindow.h \
  60     daynavigatorwidget.h \
  61     eventdialog.h \
  62     tabcontainer.h \
  63     settingsdialog.h \
  64     conferenceeditor.h \
  65     urlinputdialog.h
  66
  67 SOURCES += roomstabcontainer.cpp \
  68     trackstabcontainer.cpp \
  69     favtabcontainer.cpp \
  70     searchtabcontainer.cpp \
  71     searchhead.cpp \
  72     dayviewtabcontainer.cpp \
  73     conflictdialogcontainer.cpp \
  74     conflictsdialog.cpp \
  75     mainwindow.cpp \
  76     daynavigatorwidget.cpp \
  77     eventdialog.cpp \
  78     tabcontainer.cpp \
  79     settingsdialog.cpp \
  80     conferenceeditor.cpp \
  81     urlinputdialog.cpp
  82
  83 HEADERS += errormessage.h
  84 SOURCES += errormessage.cpp
  85 CONFIG(maemo5) {
  86     QT += maemo5
  87 }
  88