confclerk.pro

   1 # confclerk.pro
   2
   3 QMAKEVERSION = $$[QMAKE_VERSION]
   4 ISQT4 = $$find(QMAKEVERSION, ^[2-9])
   5 isEmpty( ISQT4 ) {
   6         error("Use the qmake include with Qt4.7 or greater, on Debian that is qmake-qt4");
   7 }
   8
   9 TEMPLATE = subdirs
  10 SUBDIRS = src
  11
  12 # The global.pri defines the VERSION of the project
  13 include(src/global.pri)
  14
  15 QMAKE_EXTRA_TARGETS += changelog icon man release releaseclean tarball signature
  16
  17 changelog.target = ChangeLog
  18 changelog.commands = \
  19         git pull && /usr/share/gnulib/build-aux/gitlog-to-changelog > ChangeLog
  20 changelog.CONFIG = phony
  21
  22 icon.target = data/$${TARGET}.png
  23 icon.commands = convert -transparent white data/$${TARGET}.svg data/$${TARGET}.png
  24 icon.depends = data/$${TARGET}.svg
  25
  26 man.target = data/$${TARGET}.1
  27 man.commands = \
  28         pod2man --utf8 --center=\"Offline conference scheduler\" --release=\"Version $${VERSION}\" data/$${TARGET}.pod > data/$${TARGET}.1
  29 man.depends = data/$${TARGET}.pod
  30
  31 releaseclean.commands = \
  32  $(DEL_FILE) data/$${TARGET}.png data/$${TARGET}.1 ChangeLog $${TARGET}-$${VERSION}.tar.gz.asc
  33 release.depends = distclean releaseclean tarball signature
  34 #releaseclean.CONFIG = phony
  35
  36 tarball.target = $${TARGET}-$${VERSION}.tar.gz
  37 tarball.commands = \
  38         $(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
  39         $(MKDIR) $${TARGET}-$${VERSION} ; \
  40         $(COPY_DIR) * $${TARGET}-$${VERSION}/ ; \
  41         $(DEL_FILE) $${TARGET}-$${VERSION}/*.pro.user* \
  42                 $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION}.tar.gz \
  43                 $(DEL_FILE) -r $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION} \
  44                 $${TARGET}-$${VERSION}/Makefile ; \
  45         tar -cz --exclude=.svn --exclude=.git --exclude=*.tar.gz -f $$tarball.target $${TARGET}-$${VERSION} ; \
  46         $(DEL_FILE) -r $${TARGET}-$${VERSION}
  47 tarball.depends = changelog icon man
  48
  49 signature.target = $${TARGET}-$${VERSION}.tar.gz.asc
  50 signature.commands = \
  51         gpg --armor --detach-sign $${TARGET}-$${VERSION}.tar.gz
  52 signature.depends = tarball