zavai/gsm.vala

   1 /*
   2  * gsm - gsm resource for zavai
   3  *
   4  * Copyright (C) 2009--2010  Enrico Zini <enrico@enricozini.org>
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19  */
  20
  21 using GLib;
  22
  23 namespace zavai {
  24 namespace gsm {
  25
  26 [DBus (name = "org.freesmartphone.GSM.Device")]
  27 public interface FSO_GSM_Device : Object {
  28     public abstract async int test_int (int i, out int j) throws DBus.Error;
  29     public abstract async string test_string (string s, out string t) throws DBus.Error;
  30     public abstract async void set_sim_buffers_sms(bool sim_buffers_sms) throws DBus.Error;
  31     public abstract async void set_r_t_c() throws DBus.Error;
  32     public abstract async void cancel_command() throws DBus.Error;
  33     public abstract async void set_antenna_power(bool power) throws DBus.Error;
  34     public abstract async GLib.HashTable<string, GLib.Value?> get_info() throws DBus.Error;
  35     public abstract async void set_microphone_muted(bool muted) throws DBus.Error;
  36     public signal void keypad_event(string name, bool pressed);
  37     public abstract async int get_speaker_volume() throws DBus.Error;
  38     public abstract async int get_r_t_c() throws DBus.Error;
  39     public abstract async void set_speaker_volume(int modem_volume) throws DBus.Error;
  40     public abstract async GLib.HashTable<string, GLib.Value?> get_features() throws DBus.Error;
  41     public abstract async bool get_microphone_muted() throws DBus.Error;
  42     public abstract async bool get_antenna_power() throws DBus.Error;
  43     public abstract async void get_power_status(out string param0, out int param1) throws DBus.Error;
  44     public abstract async bool get_sim_buffers_sms() throws DBus.Error;
  45 }
  46
  47 [DBus (name = "org.freesmartphone.GSM.SIM")]
  48 public interface FSO_GSM_SIM : GLib.Object {
  49     //public abstract async SIMParam0Struct[] retrieve_phonebook(string category) throws DBus.Error;
  50     public abstract async void send_auth_code(string code) throws DBus.Error;
  51     public abstract async string get_issuer() throws DBus.Error;
  52     public abstract async void change_auth_code(string old_pin, string new_pin) throws DBus.Error;
  53     public signal void auth_status(string status);
  54     public abstract async string send_generic_sim_command(string command) throws DBus.Error;
  55     public abstract async string[] list_phonebooks() throws DBus.Error;
  56     public abstract async void set_service_center_number(string number) throws DBus.Error;
  57     public abstract async GLib.HashTable<string, string> get_provider_list() throws DBus.Error;
  58     //public abstract async SIMParam0Struct2[] get_home_zones() throws DBus.Error;
  59     public signal void ready_status(bool status);
  60     public abstract async void retrieve_entry(string category, int index, out string param0, out string param1) throws DBus.Error;
  61     public abstract async void delete_message(int index) throws DBus.Error;
  62     public abstract async void send_restricted_sim_command(int command, int fileid, int p1, int p2, int p3, string data, out int param0, out int param1, out string param2) throws DBus.Error;
  63     public abstract async GLib.HashTable<string, GLib.Value?> get_messagebook_info() throws DBus.Error;
  64     public abstract async bool get_sim_ready() throws DBus.Error;
  65     public abstract async GLib.HashTable<string, GLib.Value?> get_phonebook_info(string category) throws DBus.Error;
  66     public signal void memory_full();
  67     public abstract async GLib.HashTable<string, GLib.Value?> get_sim_info() throws DBus.Error;
  68     public abstract async void set_auth_code_required(bool required, string pin) throws DBus.Error;
  69     public abstract async string get_auth_status() throws DBus.Error;
  70     public abstract async void send_stored_message(int index, out int param0, out string param1) throws DBus.Error;
  71     public abstract async int store_message(string number, string contents, GLib.HashTable<string, GLib.Value?> properties) throws DBus.Error;
  72     public abstract async bool get_auth_code_required() throws DBus.Error;
  73     public signal void incoming_stored_message(int index);
  74     public abstract async void retrieve_message(int index, out string param0, out string param1, out string param2, out GLib.HashTable<string, GLib.Value?> param3) throws DBus.Error;
  75     public abstract async void store_entry(string category, int index, string name, string number) throws DBus.Error;
  76     public abstract async void unlock(string puk, string new_pin) throws DBus.Error;
  77     public abstract async string get_service_center_number() throws DBus.Error;
  78     //public abstract async SIMParam0Struct23[] retrieve_messagebook(string category) throws DBus.Error;
  79     public abstract async void delete_entry(string category, int index) throws DBus.Error;
  80 }
  81
  82 [DBus (name = "org.freesmartphone.GSM.Network")]
  83 public interface FSO_GSM_Network : GLib.Object {
  84     public signal void status(GLib.HashTable<string, GLib.Value?> status);
  85     public signal void signal_strength(int strength);
  86     //public abstract async NetworkParam0Struct[] list_providers() throws DBus.Error;
  87     public abstract async GLib.HashTable<string, GLib.Value?> get_call_forwarding(string reason) throws DBus.Error;
  88     public signal void time_zone_report(int timezone);
  89     public abstract async void unregister() throws DBus.Error;
  90     public abstract async void set_calling_identification(string status) throws DBus.Error;
  91     public abstract async void register_() throws DBus.Error;
  92     public abstract async void send_ussd_request(string request) throws DBus.Error;
  93     public abstract async void disable_call_forwarding(string reason, string class_) throws DBus.Error;
  94     public signal void incoming_ussd(string mode, string message_);
  95     public abstract async int get_signal_strength() throws DBus.Error;
  96     public abstract async void enable_call_forwarding(string reason, string class_, string number, int timeout) throws DBus.Error;
  97     public abstract async string get_calling_identification() throws DBus.Error;
  98     public abstract async void register_with_provider(string operator_code) throws DBus.Error;
  99     public signal void cipher_status(string gsm, string gprs);
 100     public abstract async GLib.HashTable<string, GLib.Value?> get_status() throws DBus.Error;
 101     public abstract async void get_country_code(out string param0, out string param1) throws DBus.Error;
 102 }
 103
 104 [DBus (name = "org.freesmartphone.GSM.Call")]
 105 public interface FSO_GSM_Call : GLib.Object {
 106     public abstract async void activate(int index) throws DBus.Error;
 107     public abstract async void emergency(string number) throws DBus.Error;
 108     public abstract async void hold_active() throws DBus.Error;
 109     public abstract async void release_held() throws DBus.Error;
 110     public abstract async void send_dtmf(string tones) throws DBus.Error;
 111     public abstract async void release_all() throws DBus.Error;
 112     public abstract async int initiate(string number, string type_) throws DBus.Error;
 113     // public abstract async CallParam0Struct[] list_calls() throws DBus.Error;
 114     public abstract async void transfer(string number) throws DBus.Error;
 115     public abstract async void release(int index) throws DBus.Error;
 116     public signal void call_status(int index, string status, GLib.HashTable<string, GLib.Value?> properties);
 117     public abstract async void activate_conference(int index) throws DBus.Error;
 118 }
 119
 120 public class GSM: zavai.ScriptMonitorService
 121 {
 122     protected dynamic DBus.Object dbus;
 123     public FSO_GSM_Device device;
 124     public FSO_GSM_Network network;
 125     public FSO_GSM_SIM sim;
 126     public FSO_GSM_Call call;
 127
 128     protected class CallInfo
 129     {
 130         public int gsm_id;
 131         public uint log_id;
 132     }
 133     protected List<CallInfo> calls;
 134
 135     public string info_provider;
 136     public int info_signal_strength;
 137
 138     public signal void status_changed(string message);
 139     public signal void info_changed();
 140
 141     protected void dump_table(HashTable<string, Value?> vals)
 142     {
 143         vals.for_each((pk, pv) => {
 144             string k = (string)pk;
 145             Value? v = (Value?)pv;
 146             stderr.printf("K: %s V: %s\n", k, v == null ? "(null)" : v.strdup_contents());
 147         });
 148     }
 149
 150     protected void acquire_new_status(HashTable<string, Value?> status)
 151     {
 152         // NETWORK STATUS
 153         // K: provider V: "vodafone UK"
 154         // K: mode V: "automatic"
 155         // K: registration V: "roaming"
 156         // K: cid V: "157F"
 157         // K: lac V: "0031"
 158         // K: act V: "GSM"
 159         // K: code V: "23415"
 160         bool changed = false;
 161
 162         var vprovider = status.lookup("provider");
 163         if (vprovider != null)
 164         {
 165             if (info_provider != vprovider.get_string())
 166             {
 167                 info_provider = vprovider.get_string();
 168 stderr.printf("ACQUIRE PROV %s\n", info_provider);
 169                 changed = true;
 170             }
 171         }
 172
 173         if (changed)
 174         {
 175 stderr.printf("NOTIFY CHANGED\n");
 176             info_changed();
 177         }
 178     }
 179
 180     protected void acquire_new_signal_strength(int strength)
 181     {
 182         if (info_signal_strength != strength)
 183         {
 184             info_signal_strength = strength;
 185 stderr.printf("ACQUIRE SIG %d\n", info_signal_strength);
 186             info_changed();
 187         }
 188     }
 189
 190     public GSM()
 191     {
 192         Object(name: "gsm");
 193
 194         calls = new List<CallInfo>();
 195
 196         device = (FSO_GSM_Device)zavai.registry.sbus.get_object(
 197                 "org.freesmartphone.ogsmd",
 198                 "/org/freesmartphone/GSM/Device",
 199                 "org.freesmartphone.GSM.Device");
 200         network = (FSO_GSM_Network)zavai.registry.sbus.get_object(
 201             "org.freesmartphone.ogsmd",
 202             "/org/freesmartphone/GSM/Device",
 203             "org.freesmartphone.GSM.Network");
 204         sim = (FSO_GSM_SIM)zavai.registry.sbus.get_object(
 205                 "org.freesmartphone.ogsmd",
 206                 "/org/freesmartphone/GSM/Device",
 207                 "org.freesmartphone.GSM.SIM");
 208         call = (FSO_GSM_Call)zavai.registry.sbus.get_object(
 209             "org.freesmartphone.ogsmd",
 210             "/org/freesmartphone/GSM/Device",
 211             "org.freesmartphone.GSM.Call");
 212         dbus = zavai.registry.sbus.get_object(
 213                 "org.freedesktop.DBus",
 214                 "/org/freedesktop/DBus",
 215                 "org.freedesktop.DBus");
 216         dbus.NameOwnerChanged += on_name_owner_changed;
 217
 218         info_provider = "(unknown)";
 219         info_signal_strength = -1;
 220
 221         network.status += (status) => {
 222             stderr.printf("NETWORK STATUS\n");
 223             dump_table(status);
 224             acquire_new_status(status);
 225         };
 226
 227         network.signal_strength += (strength) => {
 228             stderr.printf("SIGNAL STRENGTH %d\n", strength);
 229             acquire_new_signal_strength(strength);
 230         };
 231
 232         call.call_status += on_call_status;
 233     }
 234
 235     /// Request GPS resource
 236     public override void start()
 237     {
 238         if (started) return;
 239
 240         status_changed("Starting");
 241
 242         script_start();
 243
 244         base.start();
 245     }
 246
 247     protected void on_name_owner_changed(DBus.Object sender, string name, string oldOwner, string newOwner)
 248     {
 249         zavai.log.debug("NOC " + name + " from " + oldOwner + " to " + newOwner);
 250         if (name == "org.freesmartphone.ogsmd" && newOwner != "")
 251         {
 252             status_changed("ogpsd came online");
 253             start_gsm.begin();
 254         }
 255     }
 256
 257     // Release usage of GPS
 258     public override void stop()
 259     {
 260         if (!started) return;
 261
 262         script_stop();
 263
 264         status_changed("");
 265         info_provider = "";
 266         info_signal_strength = -1;
 267         info_changed();
 268     }
 269
 270     protected override void cleanup_after_script_stop()
 271     {
 272         call = null;
 273     }
 274
 275     public async void start_gsm()
 276     {
 277         status_changed("Turning on antenna");
 278         while (true)
 279         {
 280             try {
 281                 yield device.set_antenna_power(true);
 282                 break;
 283             } catch (Error e) {
 284                 zavai.log.warning("SetAntennaPower: " + e.message);
 285                 if (e.message.str("current status is 'enabling'") != null
 286                  || e.message.str("current status is 'unknown'") != null)
 287                 {
 288                     status_changed("Waiting for ogsmd to settle");
 289                     zavai.log.info("trying again after 2 seconds");
 290                     Timeout.add(2 * 1000, () => {
 291                         start_gsm.callback();
 292                         return false;
 293                     });
 294                     yield;
 295                 } else {
 296                     status_changed("Checking if PIN is required");
 297                     string status = yield sim.get_auth_status();
 298                     zavai.log.info("on_auth_status: " + status);
 299                     if (status == "READY")
 300                         status_changed("PIN ok");
 301                     else if (status == "SIM PIN")
 302                     {
 303                         status_changed("Sending PIN");
 304                         yield sim.send_auth_code(zavai.config.sim_pin);
 305                         status_changed("PIN OK");
 306                     }
 307                     else
 308                         zavai.log.debug("Unknown status: " + status);
 309                 }
 310             }
 311         }
 312         zavai.log.warning("on_antenna_power ok");
 313         status_changed("Registering with network");
 314         yield network.register_();
 315         status_changed("Registered with network");
 316
 317         acquire_new_status(yield network.get_status());
 318         acquire_new_signal_strength(yield network.get_signal_strength());
 319     }
 320
 321     protected CallInfo? lookup_call(int gsm_id)
 322     {
 323         for (weak List<CallInfo> i = calls; i != null; i = i.next)
 324             if (i.data.gsm_id == gsm_id)
 325                 return i.data;
 326         return null;
 327     }
 328
 329     public void on_call_status(int index, string status, HashTable<string, Value?> properties)
 330     {
 331         stderr.printf("CALL STATUS %d %s\n", index, status);
 332         dump_table(properties);
 333
 334         CallInfo? info = lookup_call(index);
 335         if (info == null)
 336         {
 337             Value? v = properties.lookup("peer");
 338             string title;
 339             if (v != null)
 340                 title = "%s call from %s".printf(status, v.get_string());
 341             else
 342                 title = "%s call".printf(status);
 343
 344             info = new CallInfo();
 345             info.gsm_id = index;
 346             info.log_id = zavai.log.log.start("call", title);
 347             calls.append(info);
 348         }
 349
 350         // Log a summary of all info
 351         string call_info = "status: %s\n".printf(status);
 352         properties.for_each((pk, pv) => {
 353             string k = (string)pk;
 354             Value? v = (Value?)pv;
 355             call_info = call_info + "%s: %s\n".printf(k, v == null ? "(null)" : v.strdup_contents());
 356         });
 357         zavai.log.log.add(info.log_id, call_info);
 358
 359         // Remove entry when it's the last possible status
 360         if (status == "release")
 361         {
 362             zavai.log.log.end(info.log_id);
 363             for (weak List<CallInfo> i = calls; i != null; i = i.next)
 364                 if (i.data.gsm_id == index)
 365                 {
 366                     calls.delete_link(i);
 367                     break;
 368                 }
 369         }
 370
 371         /*
 372         dbg("cbCallStatus %d, %s, %s" % (id, status, formatDict(properties)))
 373         self.status = status
 374         if status == "incoming":
 375             if "peer" in properties and properties["peer"] == "+358942832031":
 376                 self.gsm_call_iface.ReleaseAll()
 377                 os.system("kapula-debug-call-handler &")
 378             else:
 379                 os.system("alsactl restore -f /etc/alsa-scenarios/stereoout-maxvolume.state")
 380                 os.system("vibrator-start")
 381                 os.system("ringtone-start")
 382                 os.system("ledctrl --on-time 400 --off-time 200 gta02-aux:red");
 383         if status == "release":
 384             os.system("ringtone-stop")
 385             os.system("vibrator-stop")
 386             os.system("ledctrl --off gta02-aux:red");
 387         */
 388     }
 389 }
 390
 391 public class GPRS: zavai.Service
 392 {
 393     public dynamic DBus.Object device;
 394
 395     public GPRS()
 396     {
 397         Object(name: "gsm.gprs");
 398
 399         device = zavai.registry.sbus.get_object(
 400             "org.freesmartphone.ogsmd",
 401             "/org/freesmartphone/GSM/Device",
 402             "org.freesmartphone.GSM.PDP");
 403     }
 404
 405     /// Request GPS resource
 406     public override void start()
 407     {
 408         if (started) return;
 409         try {
 410             //gsm.request(name);
 411             device.ActivateContext(
 412                 zavai.config.gprs_apn,
 413                 zavai.config.gprs_user,
 414                 zavai.config.gprs_pass);
 415             zavai.log.info("Started GPRS");
 416             base.start();
 417         } catch (GLib.Error e) {
 418             zavai.log.error(e.message);
 419         }
 420         base.start();
 421     }
 422
 423     // Release usage of GPS
 424     public override void stop()
 425     {
 426         if (!started) return;
 427         try {
 428             //gsm.release(name);
 429             device.DeactivateContext();
 430             zavai.log.info("Stopped GPRS");
 431             base.stop();
 432         } catch (GLib.Error e) {
 433             zavai.log.error(e.message);
 434         }
 435         base.stop();
 436     }
 437 }
 438
 439 public zavai.gsm.GSM gsm = null;
 440 public zavai.gsm.GPRS gprs = null;
 441
 442 public void init()
 443 {
 444     gsm = new GSM();
 445     gprs = new GPRS();
 446 }
 447
 448 }
 449 }