24a94c2839a204d4e87e44dcceed20b231865add
[gregoa/zavai.git] / src / app.vala
1 /*
2  * app - zavai main window
3  *
4  * Copyright (C) 2009  Enrico Zini <enrico@enricozini.org>
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License as published by
8  * the Free Software Foundation; either version 2 of the License, or
9  * (at your option) any later version.
10  *
11  * This program is distributed in the hope that it will be useful,
12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14  * GNU General Public License for more details.
15  *
16  * You should have received a copy of the GNU General Public License
17  * along with this program; if not, write to the Free Software
18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
19  */
20
21 using GLib;
22
23 namespace zavai {
24
25 public class Zavai : Gtk.Window, zavai.Resource
26 {
27     public bool visibility = true;
28     public signal void visibility_changed(bool visible);
29
30     zavai.Applet current;
31
32     public Zavai()
33     {
34         title = "Zavai";
35         current = null;
36         destroy += Gtk.main_quit;
37         set_events(get_events() | Gdk.EventMask.VISIBILITY_NOTIFY_MASK);
38         visibility_notify_event += on_visibility;
39         set_skip_pager_hint(true);
40         set_skip_taskbar_hint(true);
41         //set_type_hint(Gdk.WindowTypeHint.DESKTOP);
42
43         zavai.registry.register(this);
44     }
45
46     private bool on_visibility(Gdk.Event event)
47     {
48         visibility = (event.visibility.state == Gdk.VisibilityState.UNOBSCURED);
49         //visible = visibility;
50         visibility_changed(visibility);
51         return true;
52     }
53
54     public void toggle_visibility()
55     {
56         if (visibility)
57         {
58             visible = false;
59             visibility = false;
60             visibility_changed(visibility);
61             //zavai.app.iconify();
62         } else {
63             visible = true;
64             present();
65             set_skip_pager_hint(true);
66             set_skip_taskbar_hint(true);
67         }
68     }
69
70     public void ensure_visible()
71     {
72         if (!visibility)
73         {
74             visible = true;
75             present();
76             set_skip_pager_hint(true);
77             set_skip_taskbar_hint(true);
78         }
79     }
80
81     public void ensure_hidden()
82     {
83         if (visibility)
84         {
85             visible = false;
86             visibility = false;
87             visibility_changed(visibility);
88         }
89     }
90
91     public void show_applet(Applet applet)
92     {
93         // Remove the current applet
94         if (current != null)
95         {
96             current.stop();
97             remove(current);
98             current = null;
99         }
100
101         // Add the new applet
102         current = applet;
103         add(current);
104         current.start();
105         current.show_all();
106     }
107
108     public void push_applet(Applet applet)
109     {
110         // Make the function idempotent
111         if (current == applet)
112             return;
113
114         // Remove the current applet
115         if (current != null)
116         {
117 //stderr.printf("push applet remove %s\n", current_name);
118             applet.back_link = current;
119             current.stop();
120             remove(current);
121             current = null;
122         }
123
124 //stderr.printf("push applet add %s\n", name);
125         // Add the new applet
126         current = applet;
127         add(current);
128         current.start();
129         current.show_all();
130     }
131
132     public void back()
133     {
134         if (current != null)
135             current.back();
136     }
137
138     public void back_to_main()
139     {
140         show_applet(zavai.ui.main.status);
141     }
142
143     public void shutdown()
144     {
145     }
146
147     public void run()
148     {
149         set_size_request(300, 500);
150         //fullscreen();
151         show_all();
152     }
153
154     public void run_script(string command)
155     {
156         zavai.log.info("Run program: " + command);
157         string[] args = command.split(" ");
158         Pid pid;
159         try {
160             Process.spawn_async(
161                 Environment.get_home_dir(),
162                 args,
163                 null,
164                 SpawnFlags.SEARCH_PATH,
165                 null,
166                 out pid);
167         } catch (SpawnError e) {
168             zavai.log.error("Running " + command + ": " + e.message);
169         }
170     }
171 }
172
173 public abstract class Applet : Gtk.VBox, Resource
174 {
175     // 'label' property: label to show in window title or button names
176     protected string _label;
177     public string label {
178         get { return this._label; }
179         set {
180             if (_label != value)
181             {
182                 _label = value;
183                 label_changed();
184             }
185         }
186     }
187     public signal void label_changed();
188
189     protected Gtk.HBox button_box;
190
191     // 'back_link' property: link to use to "go back". If null, do not show
192     // a way to go back.
193     protected AppletLink _back_link = null;
194     public Applet back_link {
195         get { return _back_link.target; }
196         set {
197 //stderr.printf("Set back link of %s to %s\n", _label, value);
198             if (value == null && _back_link != null)
199             {
200                 _back_link.target = value;
201                 button_box.remove(_back_link);
202             } else if (value != null) {
203                 if (_back_link.target == null)
204                 {
205                     _back_link.target = value;
206                     button_box.pack_end(_back_link, true, true, 0);
207                     _back_link.show();
208                 } else
209                     _back_link.target = value;
210             }
211         }
212     }
213
214     public Applet()
215     {
216         button_box = new Gtk.HBox(true, 0);
217         this.homogeneous = false;
218         this.spacing = 0;
219         pack_end(button_box, false, true, 0);
220         _back_link = new AppletStraightLink();
221         zavai.registry.register(this);
222     }
223
224     public virtual void back()
225     {
226         _back_link.activate_applet();
227     }
228
229     public virtual void back_to_main()
230     {
231         zavai.app.back_to_main();
232     }
233
234     public void shutdown()
235     {
236         stop();
237     }
238
239     public virtual void start() {}
240     public virtual void stop() {}
241 }
242
243 public class Menu : Applet
244 {
245     public Menu(string label)
246     {
247         _label = label;
248     }
249
250     public void add_applet(Applet target)
251     {
252         pack_start(new AppletPushLink(target), false, false, 0);
253     }
254
255     public void add_service_toggle(Service service, string label_start, string label_stop)
256     {
257         pack_start(new ServiceRequestLink(service, label_start, label_stop), false, false, 0);
258     }
259
260     public void add_widget(Gtk.Widget w)
261     {
262         pack_start(w, false, false, 0);
263     }
264 }
265
266 public class BigButton : Gtk.Button
267 {
268     public BigButton()
269     {
270         set_size_request(0, zavai.config.min_button_height);
271     }
272 }
273
274 public abstract class AppletLink : BigButton
275 {
276     protected Applet _target;
277     public Applet target {
278         get { return _target; }
279         set
280         {
281             if (_target != null)
282             {
283                 _target.label_changed -= on_label_changed;
284             }
285             bool was_shown = _target != null;
286             _target = value;
287             if (_target != null)
288             {
289                 set_label(_target.label);
290                 _target.label_changed += on_label_changed;
291                 if (!was_shown) show();
292             } else {
293                 if (was_shown) hide();
294             }
295         }
296     }
297
298     private void on_label_changed(Applet a)
299     {
300         set_label(a.label);
301     }
302
303     private abstract void on_clicked(Gtk.Button src);
304
305     public AppletLink(Applet? applet = null)
306     {
307         _target = null;
308         target = applet;
309
310         clicked += on_clicked;
311     }
312
313     public virtual void activate_applet()
314     {
315         on_clicked(this);
316     }
317 }
318
319 public class AppletStraightLink : AppletLink
320 {
321     private override void on_clicked(Gtk.Button src)
322     {
323 //stderr.printf("straight link: %s\n", _target);
324         if (_target != null)
325             zavai.app.show_applet(_target);
326     }
327
328     public AppletStraightLink(Applet? applet = null)
329     {
330         base(applet);
331     }
332 }
333
334 public class AppletPushLink : AppletLink
335 {
336     private override void on_clicked(Gtk.Button src)
337     {
338 //stderr.printf("push link: %s\n", _target);
339         if (_target != null)
340             zavai.app.push_applet(_target);
341     }
342
343     public AppletPushLink(Applet? applet = null)
344     {
345         base(applet);
346     }
347 }
348
349 public class ServiceRequestLink : Gtk.ToggleButton
350 {
351     protected Service service;
352     protected string label_start;
353     protected string label_stop;
354
355     private void on_toggled(Gtk.Button src)
356     {
357         if (get_active())
358             service.request("servicerequestlink");
359         else
360             service.release("servicerequestlink");
361         set_label(get_active() ? label_stop : label_start);
362     }
363
364     public ServiceRequestLink(Service service, string label_start, string label_stop)
365     {
366         this.service = service;
367         this.label_start = label_start;
368         this.label_stop = label_stop;
369         set_size_request(0, zavai.config.min_button_height);
370         toggled += on_toggled;
371
372         set_label(get_active() ? label_stop : label_start);
373     }
374 }
375
376 public class StatusIcon : Gtk.Button
377 {
378     private Gtk.Image image_widget;
379
380     public StatusIcon()
381     {
382         relief = Gtk.ReliefStyle.NONE;
383         image_widget = new Gtk.Image();
384         image = image_widget;
385     }
386
387     public void set_from_file(string file)
388     {
389         image_widget.set_from_file(file);
390     }
391
392     public void install()
393     {
394         zavai.ui.main.status.status_icons.pack_start(this, false, false, 0);
395     }
396 }
397
398
399 public zavai.Zavai app;
400 public zavai.Menu menu_main;
401 public zavai.Menu menu_gps;
402 public zavai.Menu menu_gsm;
403 public zavai.Menu menu_misc;
404
405 namespace main {
406
407 public void init()
408 {
409     zavai.app = new zavai.Zavai();
410     menu_main = new zavai.Menu("Main menu");
411
412     // Create menus
413     menu_gps = new zavai.Menu("GPS");
414     menu_main.add_applet(menu_gps);
415
416     menu_gsm = new zavai.Menu("GSM");
417     menu_main.add_applet(menu_gsm);
418
419     menu_misc = new zavai.Menu("Misc");
420     menu_main.add_applet(menu_misc);
421 }
422
423 }
424
425 }