Use font description from widget for the renderers
[gregoa/zavai.git] / src / fisheye.vala
1 /*
2  * zavai - simple interface to the OpenMoko (or to the FSO stack)
3  *
4  * Copyright (C) 2009  Enrico Zini <enrico@enricozini.org>
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License as published by
8  * the Free Software Foundation; either version 2 of the License, or
9  * (at your option) any later version.
10  *
11  * This program is distributed in the hope that it will be useful,
12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14  * GNU General Public License for more details.
15  *
16  * You should have received a copy of the GNU General Public License
17  * along with this program; if not, write to the Free Software
18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
19  */
20
21 using GLib;
22
23 public class FisheyeList : Gtk.DrawingArea
24 {
25         protected Gtk.TreeModel model;
26         protected Gdk.Pixmap background;
27         protected Gdk.Pixmap backing_store;
28
29         // Pango layouts cached for speed
30         protected const int steps = 5;
31         protected Gtk.CellRendererText[] renderers;
32
33         // Labels to show, extracted from the model
34         protected string[] label_cache;
35         protected bool base_layout_needed;
36
37         protected int cur_el;
38
39         // Layout information
40         protected int focus_first;
41         protected int focus_end;
42         protected int[] focus_starts;
43         protected bool focus_locked;
44         protected bool focus_layout_needed;
45
46         protected int _focus_size;
47         public int focus_size {
48                 get { return _focus_size; }
49                 set {
50                         _focus_size = value;
51                         focus_starts = new int[value+1];
52                         focus_layout_needed = true;
53                         queue_draw();
54                 }
55         }
56
57         protected int _label_column;
58         public int label_column {
59                 get { return _label_column; }
60                 set {
61                         _label_column = value;
62                         base_layout_needed = true;
63                         queue_draw();
64                 }
65         }
66
67         //public virtual signal void cursor_changed ();
68         public signal void row_activated(Gtk.TreePath path);
69
70         public FisheyeList()
71         {
72                 model = null;
73                 backing_store = null;
74
75                 label_cache = null;
76
77                 renderers = new Gtk.CellRendererText[steps];
78
79                 // Defaults for properties
80                 focus_size = 21;
81                 label_column = 0;
82
83                 cur_el = 0;
84                 focus_locked = false;
85
86                 add_events(Gdk.EventMask.POINTER_MOTION_MASK
87                          | Gdk.EventMask.BUTTON_PRESS_MASK
88                          | Gdk.EventMask.BUTTON_RELEASE_MASK);
89         }
90
91         public unowned Gtk.TreeModel get_model() { return model; }
92         public void set_model (Gtk.TreeModel? model)
93         {
94                 if (this.model != null)
95                 {
96                         this.model.row_changed -= on_row_changed;
97                         this.model.row_deleted -= on_row_deleted;
98                         this.model.row_has_child_toggled -= on_row_has_child_toggled;
99                         this.model.row_inserted -= on_row_inserted;
100                         this.model.rows_reordered -= on_rows_reordered;
101                 }
102                 this.model = model;
103                 this.model.row_changed += on_row_changed;
104                 this.model.row_deleted += on_row_deleted;
105                 this.model.row_has_child_toggled += on_row_has_child_toggled;
106                 this.model.row_inserted += on_row_inserted;
107                 this.model.rows_reordered += on_rows_reordered;
108                 base_layout_needed = true;
109                 queue_draw();
110         }
111
112         private void on_row_changed(Gtk.TreePath path, Gtk.TreeIter iter) { base_layout_needed = true; }
113         private void on_row_deleted(Gtk.TreePath path) { base_layout_needed = true; }
114         private void on_row_has_child_toggled(Gtk.TreePath path, Gtk.TreeIter iter) { base_layout_needed = true; }
115         private void on_row_inserted(Gtk.TreePath path, Gtk.TreeIter iter) { base_layout_needed = true; }
116         private void on_rows_reordered(Gtk.TreePath path, Gtk.TreeIter iter, void* new_order) { base_layout_needed = true; }
117
118         /* Mouse button got pressed over widget */
119         /*
120         public override bool button_press_event(Gdk.EventButton event)
121         {
122                 stderr.printf("Mouse pressed on %d %s\n", cur_el, label_cache[cur_el]);
123                 return false;
124         }
125         */
126
127         /* Mouse button got released */
128         public override bool button_release_event(Gdk.EventButton event)
129         {
130                 stderr.printf("Mouse released on %d %s\n", cur_el, label_cache[cur_el]);
131
132                 // Emit row_activated if applicable
133                 if (model != null)
134                 {
135                         Gtk.TreeIter iter;
136                         if (model.iter_nth_child(out iter, null, cur_el))
137                         {
138                                 Gtk.TreePath path = model.get_path(iter);
139                                 row_activated(path);
140                         }
141                 }
142                 return false;
143         }
144
145         /* Mouse pointer moved over widget */
146         public override bool motion_notify_event(Gdk.EventMotion event)
147         {
148                 int old_cur_el = cur_el;
149                 int x = (int)event.x;
150                 int y = (int)event.y;
151
152                 focus_locked = !focus_layout_needed && x < allocation.width/2 && y >= focus_starts[0] && y < focus_starts[focus_end - focus_first];
153
154                 if (focus_locked)
155                 {
156                         for (int idx = focus_first; idx < focus_end; ++idx)
157                                 if (y < focus_starts[idx-focus_first+1])
158                                 {
159                                         cur_el = idx;
160                                         break;
161                                 }
162
163                 } else {
164                         cur_el = y * label_cache.length / allocation.height;
165                         if (old_cur_el != cur_el)
166                                 focus_layout_needed = true;
167                 }
168
169                 //stderr.printf("MOTION %f %f CE %d\n", event.x, event.y, cur_el);
170                 if (old_cur_el != cur_el)
171                 {
172                         queue_draw();
173                         old_cur_el = cur_el;
174                 }
175                 return false;
176         }
177
178         public override bool configure_event (Gdk.EventConfigure event)
179         {
180                 base_layout_needed = true;
181                 queue_draw();
182                 return false;
183         }
184
185         /* Widget is asked to draw itself */
186         public override bool expose_event (Gdk.EventExpose event)
187         {
188                 draw();
189
190                 window.draw_drawable(
191                         get_style().fg_gc[Gtk.StateType.NORMAL],
192                         backing_store,
193                         event.area.x, event.area.y,
194                         event.area.x, event.area.y,
195                         event.area.width, event.area.height);
196
197                 return false;
198         }
199
200         public override void style_set(Gtk.Style? previous_style)
201         {
202                 base_layout_needed = true;
203         }
204         public override void direction_changed(Gtk.TextDirection previous_direction)
205         {
206                 base_layout_needed = true;
207         }
208
209         protected int el_y(int idx)
210         {
211                 // Distorted position
212                 int pos = fisheye(idx);
213                 //stderr.printf("%d %f %f\n", idx, undy, pos);
214                 return pos;
215         }
216
217         protected Gtk.CellRendererText make_cell_renderer()
218         {
219                 var res = new Gtk.CellRendererText();
220                 res.font_desc = get_style().font_desc;
221                 return res;
222         }
223
224         protected void base_layout()
225         {
226                 background = new Gdk.Pixmap(window, allocation.width, allocation.height, -1);
227                 draw_background(background);
228
229                 backing_store = new Gdk.Pixmap(window, allocation.width, allocation.height, -1);
230
231                 // Recreate the renderers
232                 renderers[renderers.length-1] = make_cell_renderer();
233                 renderers[renderers.length-1].set_fixed_height_from_font(1);
234
235                 renderers[0] = make_cell_renderer();
236                 renderers[0].size = 1;
237                 renderers[0].set_fixed_height_from_font(1);
238
239                 for (int i = 1; i < renderers.length-1; ++i)
240                 {
241                         renderers[i] = make_cell_renderer();
242                         renderers[i].scale = (double)i / renderers.length;
243                         renderers[i].set_fixed_height_from_font(1);
244                 }
245
246                 if (model == null)
247                 {
248                         label_cache = new string[0];
249                 } else {
250                         Gtk.TreeIter iter;
251                         if (!model.get_iter_first(out iter))
252                         {
253                                 label_cache = new string[0];
254                         }
255                         else
256                         {
257                                 int count = model.iter_n_children(null);
258                                 label_cache = new string[count];
259
260                                 int i = 0;
261                                 do {
262                                         string val;
263                                         model.get(iter, _label_column, out val, -1);
264                                         label_cache[i] = val;
265                                         ++i;
266                                 } while (model.iter_next(ref iter));
267                         }
268                 }
269
270                 base_layout_needed = false;
271                 focus_layout_needed = true;
272         }
273
274         protected void focus_layout()
275         {
276                 if (label_cache.length == 0)
277                 {
278                         focus_first = 0;
279                         focus_end = 0;
280                         focus_starts[0] = 0;
281                 } else {
282                         if (_focus_size >= label_cache.length)
283                         {
284                                 focus_first = 0;
285                                 focus_end = label_cache.length;
286                         } else {
287                                 focus_first = cur_el -_focus_size/2;
288                                 if (focus_first < 0) focus_first = 0;
289
290                                 focus_end = focus_first + _focus_size;
291                                 if (focus_end > label_cache.length)
292                                 {
293                                         focus_end = label_cache.length;
294                                         focus_first = focus_end - _focus_size;
295                                 }
296                         }
297
298                         // Compute starting positions for all items in focus
299                         for (int idx = focus_first; idx <= focus_end; ++idx)
300                                 focus_starts[idx - focus_first] = el_y(idx);
301                 }
302                 focus_layout_needed = false;
303         }
304
305         protected void draw_background(Gdk.Drawable drawable)
306         {
307                 Gtk.Style style = get_style();
308
309                 // Background
310                 drawable.draw_rectangle(style.bg_gc[Gtk.StateType.NORMAL], true, 0, 0, allocation.width, allocation.height);
311
312                 // Focus lock area
313                 drawable.draw_rectangle(style.bg_gc[Gtk.StateType.ACTIVE], true,
314                         0, focus_starts[0], allocation.width/2, focus_starts[focus_end - focus_first]-focus_starts[0]);
315         }
316
317         protected void draw()
318         {
319                 if (base_layout_needed)
320                         base_layout();
321                 if (focus_layout_needed)
322                         focus_layout();
323
324                 var drawable = backing_store;
325                 Gtk.Style style = get_style();
326                 Gdk.Rectangle expose_area = Gdk.Rectangle();
327                 expose_area.x = expose_area.y = 0;
328                 expose_area.width = allocation.width;
329                 expose_area.height = allocation.height;
330
331                 // Background
332                 drawable.draw_drawable(
333                         get_style().fg_gc[Gtk.StateType.NORMAL],
334                         background,
335                         0, 0, 0, 0,
336                         allocation.width, allocation.height);
337
338                 // Focus movement area
339                 drawable.draw_rectangle(style.bg_gc[Gtk.StateType.INSENSITIVE], true,
340                         allocation.width/2, 0, allocation.width, allocation.height);
341
342                 // Paint items around focus
343                 Gdk.Rectangle cell_area = Gdk.Rectangle();
344                 cell_area.x = 0;
345                 cell_area.width = allocation.width;
346                 for (int idx = 0; idx < focus_end-focus_first; ++idx)
347                 {
348                         int y0 = focus_starts[idx];
349                         int y1 = focus_starts[idx + 1];
350                         cell_area.y = y0;
351                         cell_area.height = y1-y0;
352
353                         Gtk.CellRendererState rflags = 0;
354                         if (idx + focus_first == cur_el)
355                         {
356                                 rflags |= Gtk.CellRendererState.SELECTED | Gtk.CellRendererState.FOCUSED;
357                                 drawable.draw_rectangle(style.bg_gc[Gtk.StateType.SELECTED], true,
358                                                 cell_area.x, cell_area.y, cell_area.width, cell_area.height);
359                         }
360                 
361                         int size = (y1-y0);
362                         if (size <= 0) size = 1;
363                         if (size >= renderers.length) size = renderers.length - 1;
364                         renderers[size].text = label_cache[idx + focus_first];
365                         renderers[size].render((Gdk.Window*)drawable, this, 
366                                         cell_area,
367                                         cell_area,
368                                         expose_area,
369                                         rflags);
370
371                         //Gdk.draw_line(drawable, style.fg_gc[itemState], 0, y0, allocation.width, y0);
372                 }
373         }
374
375         /*
376          * The following function is adapted from Prefuse's FisheyeDistortion.java.
377          *
378          * A relevant annotation from Prefuse:
379          *
380          * For more details on this form of transformation, see Manojit Sarkar and 
381          * Marc H. Brown, "Graphical Fisheye Views of Graphs", in Proceedings of 
382          * CHI'92, Human Factors in Computing Systems, p. 83-91, 1992. Available
383          * online at <a href="http://citeseer.ist.psu.edu/sarkar92graphical.html">
384          * http://citeseer.ist.psu.edu/sarkar92graphical.html</a>. 
385          */
386
387         /*
388          * Distorts an item's coordinate.
389          * @param x the undistorted coordinate
390          * @param coordinate of the anchor or focus point
391          * @param d disortion factor
392          * @param min the beginning of the display
393          * @param max the end of the display
394          * @return the distorted coordinate
395          */
396         private int fisheye(int idx)
397         {
398                 // Autocompute distortion factor
399                 // 20 is the pixel size of the item at centre of focus
400                 double d = label_cache.length * 20 / allocation.height;
401                 if ( d <= 1 )
402                         return idx * allocation.height / label_cache.length;
403
404                 double a = (double)cur_el * allocation.height / label_cache.length;
405                 double x = (double)idx * allocation.height / label_cache.length;
406                 double max = (double)allocation.height;
407
408                 if (idx < cur_el)
409                 {
410                         double m = a;
411                         if ( m == 0 ) m = max;
412                         double v = (double)(a - x) / m;
413                         v = (double)(d+1)/(d+(1/v));
414                         return (int)Math.round(a - m*v);
415                 } else {
416                         double m = max-a;
417                         if ( m == 0 ) m = max;
418                         double v = (double)(x - a) / m;
419                         v = (double)(d+1)/(d+(1/v));
420                         return (int)Math.round(a + m*v);
421                 }
422         }
423 }
424
425 public class Fisheye : Gtk.Window
426 {
427         public Fisheye()
428         {
429                 title = "Fisheye";
430                 destroy += Gtk.main_quit;
431
432                 var list = new FisheyeList();
433                 add(list);
434
435                 var store = new Gtk.ListStore(1, typeof(string));
436                 Gtk.TreeIter iter;
437                 var infd = FileStream.open("/tmp/names", "r");
438                 if (infd == null)
439                 {
440                         for (int i = 0; i < 300; ++i)
441                         {
442                                 store.append(out iter);
443                                 store.set(iter, 0, "Antani %d".printf(i), -1);
444                         }
445                 } else {
446                         char buf[255];
447                         while (true)
448                         {
449                                 string line = infd.gets(buf);
450                                 if (line == null)
451                                         break;
452                                 store.append(out iter);
453                                 store.set(iter, 0, line, -1);
454                         }
455                 }
456
457                 list.set_model(store);
458         }
459 }
460
461 static int main (string[] args) {
462         Gtk.init (ref args);
463
464         var fe = new Fisheye();
465         fe.set_size_request(200, 300);
466         fe.show_all();
467
468         Gtk.main();
469
470         return 0;
471 }