confclerk.pro

   1 # confclerk.pro
   2
   3 QMAKEVERSION = $$[QMAKE_VERSION]
   4 ISQT4 = $$find(QMAKEVERSION, ^[2-9])
   5 isEmpty( ISQT4 ) {
   6 error("Use the qmake include with Qt4.4 or greater, on Debian that is
   7 qmake-qt4");
   8 }
   9
  10 TEMPLATE = subdirs
  11 SUBDIRS = src
  12
  13 VERSION = 0.5.0
  14
  15 QMAKE_CLEAN += src/bin/*.a
  16 QMAKE_EXTRA_TARGETS += tarball icon changelog release
  17
  18 changelog.target = ChangeLog
  19 changelog.commands = \
  20         svn up && svn2cl --group-by-day --reparagraph
  21 changelog.CONFIG = phony
  22
  23 icon.target = data/$${TARGET}.png
  24 icon.commands = convert data/$${TARGET}.svg data/$${TARGET}.png
  25 icon.depends = data/$${TARGET}.svg
  26
  27 release.depends = tarball
  28
  29 tarball.target = $${TARGET}-$${VERSION}.tar.gz
  30 tarball.commands = \
  31         $(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
  32         $(MKDIR) $${TARGET}-$${VERSION} ; \
  33         $(COPY_DIR) --parents * $${TARGET}-$${VERSION}/ ; \
  34         tar -cz --exclude=.svn -f $$tarball.target $${TARGET}-$${VERSION} ; \
  35         $(DEL_FILE) -r $${TARGET}-$${VERSION}
  36 tarball.depends = changelog icon