confclerk.pro

   1 # confclerk.pro
   2
   3 QMAKEVERSION = $$[QMAKE_VERSION]
   4 ISQT4 = $$find(QMAKEVERSION, ^[2-9])
   5 isEmpty( ISQT4 ) {
   6         error("Use the qmake include with Qt4.7 or greater, on Debian that is qmake-qt4");
   7 }
   8
   9 TEMPLATE = subdirs
  10 SUBDIRS = src
  11
  12 # The global.pri defines the VERSION of the project
  13 include(src/global.pri)
  14
  15 QMAKE_EXTRA_TARGETS += changelog icon man release releaseclean tarball signature
  16
  17 changelog.target = ChangeLog
  18 changelog.commands = \
  19         git pull && /usr/share/gnulib/build-aux/gitlog-to-changelog > ChangeLog
  20 changelog.CONFIG = phony
  21
  22 icon.target = data/$${TARGET}.png
  23 icon.commands = convert -transparent white data/$${TARGET}.svg data/$${TARGET}.png
  24 icon.depends = data/$${TARGET}.svg
  25
  26 TODAY = $$system(date +%F)
  27 man.target = data/$${TARGET}.1
  28 man.commands = \
  29         pod2man --utf8 --center=\"Offline conference scheduler\" --release=\"Version $${VERSION}\" --date \"$${TODAY}\" data/$${TARGET}.pod > data/$${TARGET}.1
  30 man.depends = data/$${TARGET}.pod
  31
  32 releaseclean.commands = \
  33  $(DEL_FILE) data/$${TARGET}.png data/$${TARGET}.1 ChangeLog $${TARGET}-$${VERSION}.tar.gz.asc
  34 release.depends = distclean releaseclean tarball signature
  35 #releaseclean.CONFIG = phony
  36
  37 tarball.target = $${TARGET}-$${VERSION}.tar.gz
  38 tarball.commands = \
  39         $(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
  40         $(MKDIR) $${TARGET}-$${VERSION} ; \
  41         $(COPY_DIR) * $${TARGET}-$${VERSION}/ ; \
  42         $(DEL_FILE) $${TARGET}-$${VERSION}/*.pro.user* \
  43                 $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION}.tar.gz \
  44                 $(DEL_FILE) -r $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION} \
  45                 $${TARGET}-$${VERSION}/Makefile ; \
  46         tar -cz --exclude=.svn --exclude=.git --exclude=*.tar.gz -f $$tarball.target $${TARGET}-$${VERSION} ; \
  47         $(DEL_FILE) -r $${TARGET}-$${VERSION}
  48 tarball.depends = changelog icon man
  49
  50 signature.target = $${TARGET}-$${VERSION}.tar.gz.asc
  51 signature.commands = \
  52         gpg --armor --detach-sign $${TARGET}-$${VERSION}.tar.gz
  53 signature.depends = tarball