src/gui/gui.pro

   1 include(../global.pri)
   2 TEMPLATE = lib
   3 TARGET = gui
   4 DESTDIR = ../bin
   5 CONFIG += static
   6 QT += sql \
   7     xml \
   8     network
   9
  10 # module dependencies
  11 LIBS += -L$$DESTDIR \
  12     -lmvc \
  13     -lorm \
  14     -lsql
  15 INCLUDEPATH += ../orm \
  16     ../mvc \
  17     ../sql \
  18     ../app
  19 DEPENDPATH += . \
  20     ../orm \
  21     ../mvc \
  22     ../sql
  23 TARGETDEPS += $$DESTDIR/liborm.a \
  24     $$DESTDIR/libmvc.a \
  25     $$DESTDIR/libsql.a
  26 maemo {
  27     LIBS += -L$$DESTDIR \
  28         -lqalarm
  29     INCLUDEPATH += ../alarm
  30     DEPENDPATH += ../alarm
  31     TARGETDEPS += $$DESTDIR/libqalarm.a
  32 }
  33
  34 # A shamelessly long list of sources, headers and forms.
  35 # Please note that resources MUST be added to the app module
  36 # (which means they need to be added to the test module as well,
  37 # but I am sure you can live with that for the time being).
  38
  39 FORMS += searchhead.ui \
  40     mainwindow.ui \
  41     daynavigatorwidget.ui \
  42     importschedulewidget.ui \
  43     about.ui \
  44     eventdialog.ui \
  45     conflictsdialog.ui \
  46     tabcontainer.ui \
  47     mapwindow.ui \
  48     proxysettingsdialog.ui
  49
  50 HEADERS += roomstabcontainer.h \
  51     nowtabcontainer.h \
  52     trackstabcontainer.h \
  53     favtabcontainer.h \
  54     searchtabcontainer.h \
  55     searchhead.h \
  56     dayviewtabcontainer.h \
  57     conflictdialogcontainer.h \
  58     conflictsdialog.h \
  59     mainwindow.h \
  60     daynavigatorwidget.h \
  61     importschedulewidget.h \
  62     eventdialog.h \
  63     tabwidget.h \
  64     tabcontainer.h \
  65     mapwindow.h \
  66     proxysettingsdialog.h
  67
  68 SOURCES += roomstabcontainer.cpp \
  69     nowtabcontainer.cpp \
  70     trackstabcontainer.cpp \
  71     favtabcontainer.cpp \
  72     searchtabcontainer.cpp \
  73     searchhead.cpp \
  74     dayviewtabcontainer.cpp \
  75     conflictdialogcontainer.cpp \
  76     conflictsdialog.cpp \
  77     mainwindow.cpp \
  78     daynavigatorwidget.cpp \
  79     importschedulewidget.cpp \
  80     eventdialog.cpp \
  81     tabwidget.cpp \
  82     tabcontainer.cpp \
  83     mapwindow.cpp \
  84     proxysettingsdialog.cpp
  85
  86 maemo {
  87     FORMS += alarmdialog.ui
  88     HEADERS += alarmdialog.h
  89     SOURCES += alarmdialog.cpp
  90 }