src/app/app.pro

   1 include(../global.pri)
   2 TEMPLATE = app
   3 TARGET = confclerk
   4 DESTDIR = ../bin
   5 QT += sql xml network
   6 CONFIG(maemo5) {
   7     QT += maemo5 dbus
   8 }
   9
  10 # module dependencies
  11 LIBS += -L$$DESTDIR -lgui -lmvc -lsql
  12 INCLUDEPATH += ../gui ../sql ../mvc ../orm
  13 DEPENDPATH += . ../gui
  14 POST_TARGETDEPS += $$DESTDIR/libmvc.a $$DESTDIR/libgui.a $$DESTDIR/libsql.a
  15 maemo {
  16     LIBS += -L$$DESTDIR -lqalarm -lalarm
  17     INCLUDEPATH += ../alarm
  18     DEPENDPATH +=  ../alarm
  19     POST_TARGETDEPS += $$DESTDIR/libqalarm.a
  20     HEADERS += alarmdbus.h \
  21         alarmdbusadaptorp.h
  22     SOURCES += alarmdbus.cpp \
  23         alarmdbusadaptor.cpp
  24 }
  25
  26 HEADERS += appsettings.h \
  27         application.h
  28
  29 SOURCES += main.cpp \
  30            application.cpp \
  31            appsettings.cpp
  32
  33 RESOURCES += ../icons.qrc \
  34                          ../db.qrc \
  35                          ../../data/data.qrc
  36
  37 # instalation related
  38 PREFIX = /usr/bin
  39 INSTALLS = target
  40 target.path = $$PREFIX
  41