src/gui/gui.pro

   1 include(../global.pri)
   2 TEMPLATE = lib
   3 TARGET = gui
   4 DESTDIR = ../bin
   5 CONFIG += static
   6 QT += sql xml
   7
   8 # module dependencies
   9 LIBS += -L$$DESTDIR -lmvc -lorm -lsql
  10 INCLUDEPATH += ../orm ../mvc ../sql ../app
  11 DEPENDPATH += . ../orm ../mvc ../sql
  12 TARGETDEPS += $$DESTDIR/liborm.a $$DESTDIR/libmvc.a $$DESTDIR/libsql.a
  13 maemo {
  14     LIBS += -L$$DESTDIR -lqalarm
  15     INCLUDEPATH += ../alarm
  16     DEPENDPATH +=  ../alarm
  17     TARGETDEPS +=  $$DESTDIR/libqalarm.a
  18 }
  19
  20
  21 # A shamelessly long list of sources, headers and forms.
  22 # Please note that resources MUST be added to the app module
  23 # (which means they need to be added to the test module as well,
  24 # but I am sure you can live with that for the time being).
  25
  26 FORMS += mainwindow.ui \
  27          daynavigatorwidget.ui \
  28          importschedulewidget.ui \
  29          about.ui \
  30          eventdialog.ui \
  31          mapwindow.ui
  32
  33 HEADERS += mainwindow.h \
  34            daynavigatorwidget.h \
  35            importschedulewidget.h \
  36            eventdialog.h \
  37            tabwidget.h \
  38            mapwindow.h
  39
  40 SOURCES += mainwindow.cpp \
  41            daynavigatorwidget.cpp \
  42            importschedulewidget.cpp \
  43            eventdialog.cpp \
  44            tabwidget.cpp \
  45            mapwindow.cpp
  46
  47 maemo {
  48     FORMS += alarmdialog.ui
  49     HEADERS += alarmdialog.h
  50     SOURCES += alarmdialog.cpp
  51 }
  52