src/app.vala

   1 /*
   2  * app - zavai main window
   3  *
   4  * Copyright (C) 2009  Enrico Zini <enrico@enricozini.org>
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19  */
  20
  21 using GLib;
  22
  23 namespace zavai {
  24
  25 public class Zavai : Gtk.Window, zavai.Resource
  26 {
  27         public bool visibility = true;
  28         public signal void visibility_changed(bool visible);
  29
  30         zavai.Applet current;
  31         string current_name;
  32
  33         public Zavai()
  34         {
  35                 title = "Zavai";
  36                 current = null;
  37                 current_name = null;
  38                 destroy += Gtk.main_quit;
  39                 set_events(get_events() | Gdk.EventMask.VISIBILITY_NOTIFY_MASK);
  40                 visibility_notify_event += on_visibility;
  41                 set_skip_pager_hint(true);
  42                 set_skip_taskbar_hint(true);
  43                 //set_type_hint(Gdk.WindowTypeHint.DESKTOP);
  44         }
  45
  46         private bool on_visibility(Gdk.Event event)
  47         {
  48                 visibility = (event.visibility.state == Gdk.VisibilityState.UNOBSCURED);
  49                 visibility_changed(visibility);
  50                 return true;
  51         }
  52
  53         public void toggle_visibility()
  54         {
  55                 if (visibility)
  56                 {
  57                         visible = false;
  58                         visibility = false;
  59                         visibility_changed(visibility);
  60                         //zavai.app.iconify();
  61                 } else {
  62                         visible = true;
  63                         present();
  64                         set_skip_pager_hint(true);
  65                         set_skip_taskbar_hint(true);
  66                 }
  67         }
  68
  69         /*
  70         public void hide_window()
  71         {
  72                 visible = false;
  73                 visibility = false;
  74                 visibility_changed(visibility);
  75         }
  76         */
  77
  78         public void ensure_visible()
  79         {
  80                 if (!visibility)
  81                 {
  82                         visible = true;
  83                         present();
  84                         set_skip_pager_hint(true);
  85                         set_skip_taskbar_hint(true);
  86                 }
  87         }
  88
  89         public void show_applet(string name)
  90         {
  91                 zavai.Applet applet = zavai.registry.geta(name);
  92
  93                 // Remove the current applet
  94                 if (current != null)
  95                 {
  96                         current.stop();
  97                         remove(current);
  98                         current = null;
  99                         current_name = null;
 100                 }
 101
 102                 // Add the new applet
 103                 current = applet;
 104                 current_name = name;
 105                 add(current);
 106                 current.start();
 107                 current.show_all();
 108         }
 109
 110         public void push_applet(string name)
 111         {
 112                 // Make the function idempotent
 113                 if (current_name == name)
 114                         return;
 115
 116 //stderr.printf("push applet %s -> %s\n", current_name, name);
 117                 zavai.Applet applet = zavai.registry.geta(name);
 118
 119                 // Remove the current applet
 120                 if (current != null)
 121                 {
 122 //stderr.printf("push applet remove %s\n", current_name);
 123                         applet.back_link = current_name;
 124                         current.stop();
 125                         remove(current);
 126                         current = null;
 127                         current_name = null;
 128                 }
 129
 130 //stderr.printf("push applet add %s\n", name);
 131                 // Add the new applet
 132                 current = applet;
 133                 current_name = name;
 134                 add(current);
 135                 current.start();
 136                 current.show_all();
 137         }
 138
 139         public void back()
 140         {
 141                 if (current != null)
 142                         current.back();
 143         }
 144
 145         public void back_to_main()
 146         {
 147                 show_applet("zavai.status");
 148         }
 149
 150         public void shutdown()
 151         {
 152         }
 153
 154         public void run()
 155         {
 156                 set_size_request(300, 500);
 157                 //fullscreen();
 158                 show_all();
 159         }
 160
 161         public void run_script(string command)
 162         {
 163                 zavai.log.info("Run program: " + command);
 164                 string[] args = command.split(" ");
 165                 Pid pid;
 166                 try {
 167                         Process.spawn_async(
 168                                 Environment.get_home_dir(),
 169                                 args,
 170                                 null,
 171                                 SpawnFlags.SEARCH_PATH,
 172                                 null,
 173                                 out pid);
 174                 } catch (SpawnError e) {
 175                         zavai.log.error("Running " + command + ": " + e.message);
 176                 }
 177         }
 178 }
 179
 180 public abstract class Applet : Gtk.VBox, Resource
 181 {
 182         // 'label' property: label to show in window title or button names
 183         protected string _label;
 184         public string label {
 185                 get { return this._label; }
 186                 set {
 187                         if (_label != value)
 188                         {
 189                                 _label = value;
 190                                 label_changed();
 191                         }
 192                 }
 193         }
 194         public signal void label_changed();
 195
 196         protected Gtk.HBox button_box;
 197
 198         // 'back_link' property: link to use to "go back". If null, do not show
 199         // a way to go back.
 200         protected AppletLink _back_link = null;
 201         public string back_link {
 202                 get { return _back_link.target; }
 203                 set {
 204 //stderr.printf("Set back link of %s to %s\n", _label, value);
 205                         if (value == null && _back_link != null)
 206                         {
 207                                 _back_link.target = value;
 208                                 button_box.remove(_back_link);
 209                         } else if (value != null) {
 210                                 if (_back_link.target == null)
 211                                 {
 212                                         _back_link.target = value;
 213                                         button_box.pack_end(_back_link, true, true, 0);
 214                                         _back_link.show();
 215                                 } else
 216                                         _back_link.target = value;
 217                         }
 218                 }
 219         }
 220
 221         public Applet()
 222         {
 223                 button_box = new Gtk.HBox(true, 0);
 224                 this.homogeneous = false;
 225                 this.spacing = 0;
 226                 pack_end(button_box, false, true, 0);
 227                 _back_link = new AppletStraightLink();
 228         }
 229
 230         public virtual void back()
 231         {
 232                 _back_link.activate_applet();
 233         }
 234
 235         public virtual void back_to_main()
 236         {
 237                 zavai.app.back_to_main();
 238         }
 239
 240         public void shutdown()
 241         {
 242                 stop();
 243         }
 244
 245         public virtual void start() {}
 246         public virtual void stop() {}
 247 }
 248
 249 public class Menu : Applet
 250 {
 251         public Menu(string label)
 252         {
 253                 _label = label;
 254         }
 255
 256         public void add_applet(string target)
 257         {
 258                 pack_start(new AppletPushLink(target), false, false, 0);
 259         }
 260
 261         public void add_service_toggle(string service_name, string label_start, string label_stop)
 262         {
 263                 pack_start(new ServiceRequestLink(service_name, label_start, label_stop), false, false, 0);
 264         }
 265
 266         public void add_widget(Gtk.Widget w)
 267         {
 268                 pack_start(w, false, false, 0);
 269         }
 270 }
 271
 272 public class BigButton : Gtk.Button
 273 {
 274         public BigButton()
 275         {
 276                 set_size_request(0, zavai.config.min_button_height);
 277         }
 278 }
 279
 280 public abstract class AppletLink : BigButton
 281 {
 282         protected string _target;
 283         public string target {
 284                 get { return _target; }
 285                 set
 286                 {
 287                         if (_target != null)
 288                         {
 289                                 Applet a = zavai.registry.geta(_target);
 290                                 a.label_changed -= on_label_changed;
 291                         }
 292                         bool was_shown = _target != null;
 293                         _target = value;
 294                         if (_target != null)
 295                         {
 296                                 Applet a = zavai.registry.geta(_target);
 297                                 set_label(a.label);
 298                                 a.label_changed += on_label_changed;
 299                                 if (!was_shown) show();
 300                         } else {
 301                                 if (was_shown) hide();
 302                         }
 303                 }
 304         }
 305
 306         private void on_label_changed(Applet a)
 307         {
 308                 set_label(a.label);
 309         }
 310
 311         private abstract void on_clicked(Gtk.Button src);
 312
 313         public AppletLink(string? name = null)
 314         {
 315                 _target = null;
 316                 target = name;
 317
 318                 clicked += on_clicked;
 319         }
 320
 321         public virtual void activate_applet()
 322         {
 323                 on_clicked(this);
 324         }
 325 }
 326
 327 public class AppletStraightLink : AppletLink
 328 {
 329         private override void on_clicked(Gtk.Button src)
 330         {
 331 //stderr.printf("straight link: %s\n", _target);
 332                 if (_target != null)
 333                         zavai.app.show_applet(_target);
 334         }
 335
 336         public AppletStraightLink(string? name = null)
 337         {
 338                 base(name);
 339         }
 340 }
 341
 342 public class AppletPushLink : AppletLink
 343 {
 344         private override void on_clicked(Gtk.Button src)
 345         {
 346 //stderr.printf("push link: %s\n", _target);
 347                 if (_target != null)
 348                         zavai.app.push_applet(_target);
 349         }
 350
 351         public AppletPushLink(string? name = null)
 352         {
 353                 base(name);
 354         }
 355 }
 356
 357 public class ServiceRequestLink : Gtk.ToggleButton
 358 {
 359         protected string service_name;
 360         protected string label_start;
 361         protected string label_stop;
 362
 363         private void on_toggled(Gtk.Button src)
 364         {
 365                 Service s = zavai.registry.gets(service_name);
 366                 if (get_active())
 367                         s.request("servicerequestlink");
 368                 else
 369                         s.release("servicerequestlink");
 370                 set_label(get_active() ? label_stop : label_start);
 371         }
 372
 373         public ServiceRequestLink(string service_name, string label_start, string label_stop)
 374         {
 375                 this.service_name = service_name;
 376                 this.label_start = label_start;
 377                 this.label_stop = label_stop;
 378                 set_size_request(0, zavai.config.min_button_height);
 379                 toggled += on_toggled;
 380
 381                 set_label(get_active() ? label_stop : label_start);
 382         }
 383 }
 384
 385 public class StatusIcon : Gtk.Button
 386 {
 387         private Gtk.Image image_widget;
 388
 389         public StatusIcon()
 390         {
 391                 relief = Gtk.ReliefStyle.NONE;
 392                 image_widget = new Gtk.Image();
 393                 image = image_widget;
 394         }
 395
 396         public void set_from_file(string file)
 397         {
 398                 image_widget.set_from_file(file);
 399         }
 400
 401         public void install()
 402         {
 403                 zavai.ui.main.status.status_icons.pack_start(this, false, false, 0);
 404         }
 405 }
 406
 407
 408 zavai.Zavai app;
 409
 410 }