zavai/gsm.vala

   1 /*
   2  * gsm - gsm resource for zavai
   3  *
   4  * Copyright (C) 2009--2010  Enrico Zini <enrico@enricozini.org>
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19  */
  20
  21 using GLib;
  22
  23 namespace zavai {
  24 namespace gsm {
  25
  26 [DBus (name = "org.freesmartphone.GSM.Device")]
  27 public interface FSO_GSM_Device : Object {
  28     public abstract async int test_int (int i, out int j) throws DBus.Error;
  29     public abstract async string test_string (string s, out string t) throws DBus.Error;
  30     public abstract async void set_sim_buffers_sms(bool sim_buffers_sms) throws DBus.Error;
  31     public abstract async void set_r_t_c() throws DBus.Error;
  32     public abstract async void cancel_command() throws DBus.Error;
  33     public abstract async void set_antenna_power(bool power) throws DBus.Error;
  34     public abstract async GLib.HashTable<string, GLib.Value?> get_info() throws DBus.Error;
  35     public abstract async void set_microphone_muted(bool muted) throws DBus.Error;
  36     public signal void keypad_event(string name, bool pressed);
  37     public abstract async int get_speaker_volume() throws DBus.Error;
  38     public abstract async int get_r_t_c() throws DBus.Error;
  39     public abstract async void set_speaker_volume(int modem_volume) throws DBus.Error;
  40     public abstract async GLib.HashTable<string, GLib.Value?> get_features() throws DBus.Error;
  41     public abstract async bool get_microphone_muted() throws DBus.Error;
  42     public abstract async bool get_antenna_power() throws DBus.Error;
  43     public abstract async void get_power_status(out string param0, out int param1) throws DBus.Error;
  44     public abstract async bool get_sim_buffers_sms() throws DBus.Error;
  45 }
  46
  47 [DBus (name = "org.freesmartphone.GSM.SIM")]
  48 public interface FSO_GSM_SIM : GLib.Object {
  49     //public abstract async SIMParam0Struct[] retrieve_phonebook(string category) throws DBus.Error;
  50     public abstract async void send_auth_code(string code) throws DBus.Error;
  51     public abstract async string get_issuer() throws DBus.Error;
  52     public abstract async void change_auth_code(string old_pin, string new_pin) throws DBus.Error;
  53     public signal void auth_status(string status);
  54     public abstract async string send_generic_sim_command(string command) throws DBus.Error;
  55     public abstract async string[] list_phonebooks() throws DBus.Error;
  56     public abstract async void set_service_center_number(string number) throws DBus.Error;
  57     public abstract async GLib.HashTable<string, string> get_provider_list() throws DBus.Error;
  58     //public abstract async SIMParam0Struct2[] get_home_zones() throws DBus.Error;
  59     public signal void ready_status(bool status);
  60     public abstract async void retrieve_entry(string category, int index, out string param0, out string param1) throws DBus.Error;
  61     public abstract async void delete_message(int index) throws DBus.Error;
  62     public abstract async void send_restricted_sim_command(int command, int fileid, int p1, int p2, int p3, string data, out int param0, out int param1, out string param2) throws DBus.Error;
  63     public abstract async GLib.HashTable<string, GLib.Value?> get_messagebook_info() throws DBus.Error;
  64     public abstract async bool get_sim_ready() throws DBus.Error;
  65     public abstract async GLib.HashTable<string, GLib.Value?> get_phonebook_info(string category) throws DBus.Error;
  66     public signal void memory_full();
  67     public abstract async GLib.HashTable<string, GLib.Value?> get_sim_info() throws DBus.Error;
  68     public abstract async void set_auth_code_required(bool required, string pin) throws DBus.Error;
  69     public abstract async string get_auth_status() throws DBus.Error;
  70     public abstract async void send_stored_message(int index, out int param0, out string param1) throws DBus.Error;
  71     public abstract async int store_message(string number, string contents, GLib.HashTable<string, GLib.Value?> properties) throws DBus.Error;
  72     public abstract async bool get_auth_code_required() throws DBus.Error;
  73     public signal void incoming_stored_message(int index);
  74     public abstract async void retrieve_message(int index, out string param0, out string param1, out string param2, out GLib.HashTable<string, GLib.Value?> param3) throws DBus.Error;
  75     public abstract async void store_entry(string category, int index, string name, string number) throws DBus.Error;
  76     public abstract async void unlock(string puk, string new_pin) throws DBus.Error;
  77     public abstract async string get_service_center_number() throws DBus.Error;
  78     //public abstract async SIMParam0Struct23[] retrieve_messagebook(string category) throws DBus.Error;
  79     public abstract async void delete_entry(string category, int index) throws DBus.Error;
  80 }
  81
  82 [DBus (name = "org.freesmartphone.GSM.Network")]
  83 public interface FSO_GSM_Network : GLib.Object {
  84     public signal void status(GLib.HashTable<string, GLib.Value?> status);
  85     public signal void signal_strength(int strength);
  86     //public abstract async NetworkParam0Struct[] list_providers() throws DBus.Error;
  87     public abstract async GLib.HashTable<string, GLib.Value?> get_call_forwarding(string reason) throws DBus.Error;
  88     public signal void time_zone_report(int timezone);
  89     public abstract async void unregister() throws DBus.Error;
  90     public abstract async void set_calling_identification(string status) throws DBus.Error;
  91     public abstract async void register_() throws DBus.Error;
  92     public abstract async void send_ussd_request(string request) throws DBus.Error;
  93     public abstract async void disable_call_forwarding(string reason, string class_) throws DBus.Error;
  94     public signal void incoming_ussd(string mode, string message_);
  95     public abstract async int get_signal_strength() throws DBus.Error;
  96     public abstract async void enable_call_forwarding(string reason, string class_, string number, int timeout) throws DBus.Error;
  97     public abstract async string get_calling_identification() throws DBus.Error;
  98     public abstract async void register_with_provider(string operator_code) throws DBus.Error;
  99     public signal void cipher_status(string gsm, string gprs);
 100     public abstract async GLib.HashTable<string, GLib.Value?> get_status() throws DBus.Error;
 101     public abstract async void get_country_code(out string param0, out string param1) throws DBus.Error;
 102 }
 103
 104 [DBus (name = "org.freesmartphone.GSM.Call")]
 105 public interface FSO_GSM_Call : GLib.Object {
 106     public abstract async void activate(int index) throws DBus.Error;
 107     public abstract async void emergency(string number) throws DBus.Error;
 108     public abstract async void hold_active() throws DBus.Error;
 109     public abstract async void release_held() throws DBus.Error;
 110     public abstract async void send_dtmf(string tones) throws DBus.Error;
 111     public abstract async void release_all() throws DBus.Error;
 112     public abstract async int initiate(string number, string type_) throws DBus.Error;
 113     // public abstract async CallParam0Struct[] list_calls() throws DBus.Error;
 114     public abstract async void transfer(string number) throws DBus.Error;
 115     public abstract async void release(int index) throws DBus.Error;
 116     public signal void call_status(int index, string status, GLib.HashTable<string, GLib.Value?> properties);
 117     public abstract async void activate_conference(int index) throws DBus.Error;
 118 }
 119
 120 public class GSM: zavai.ScriptMonitorService
 121 {
 122     protected dynamic DBus.Object dbus;
 123     public FSO_GSM_Device device;
 124     public FSO_GSM_Network network;
 125     public FSO_GSM_SIM sim;
 126     public FSO_GSM_Call call;
 127
 128     protected class CallInfo
 129     {
 130         public int gsm_id;
 131         public uint log_id;
 132     }
 133     protected List<CallInfo> calls;
 134
 135     public string info_provider;
 136     public int info_signal_strength;
 137
 138     public signal void status_changed(string message);
 139     public signal void info_changed();
 140
 141     protected void dump_table(HashTable<string, Value?> vals)
 142     {
 143         vals.for_each((pk, pv) => {
 144             string k = (string)pk;
 145             Value? v = (Value?)pv;
 146             stderr.printf("K: %s V: %s\n", k, v == null ? "(null)" : v.strdup_contents());
 147         });
 148     }
 149
 150     protected void acquire_new_status(HashTable<string, Value?> status)
 151     {
 152         // NETWORK STATUS
 153         // K: provider V: "vodafone UK"
 154         // K: mode V: "automatic"
 155         // K: registration V: "roaming"
 156         // K: cid V: "157F"
 157         // K: lac V: "0031"
 158         // K: act V: "GSM"
 159         // K: code V: "23415"
 160         bool changed = false;
 161
 162         var vprovider = status.lookup("provider");
 163         if (vprovider != null)
 164         {
 165             if (info_provider != vprovider.get_string())
 166             {
 167                 info_provider = vprovider.get_string();
 168                 changed = true;
 169             }
 170         }
 171
 172         if (changed)
 173             info_changed();
 174     }
 175
 176     protected void acquire_new_signal_strength(int strength)
 177     {
 178         if (info_signal_strength != strength)
 179         {
 180             info_signal_strength = strength;
 181             info_changed();
 182         }
 183     }
 184
 185     public GSM()
 186     {
 187         Object(name: "gsm");
 188
 189         calls = new List<CallInfo>();
 190
 191         device = (FSO_GSM_Device)zavai.registry.sbus.get_object(
 192                 "org.freesmartphone.ogsmd",
 193                 "/org/freesmartphone/GSM/Device",
 194                 "org.freesmartphone.GSM.Device");
 195         network = (FSO_GSM_Network)zavai.registry.sbus.get_object(
 196             "org.freesmartphone.ogsmd",
 197             "/org/freesmartphone/GSM/Device",
 198             "org.freesmartphone.GSM.Network");
 199         sim = (FSO_GSM_SIM)zavai.registry.sbus.get_object(
 200                 "org.freesmartphone.ogsmd",
 201                 "/org/freesmartphone/GSM/Device",
 202                 "org.freesmartphone.GSM.SIM");
 203         call = (FSO_GSM_Call)zavai.registry.sbus.get_object(
 204             "org.freesmartphone.ogsmd",
 205             "/org/freesmartphone/GSM/Device",
 206             "org.freesmartphone.GSM.Call");
 207         dbus = zavai.registry.sbus.get_object(
 208                 "org.freedesktop.DBus",
 209                 "/org/freedesktop/DBus",
 210                 "org.freedesktop.DBus");
 211         dbus.NameOwnerChanged += on_name_owner_changed;
 212
 213         info_provider = "(unknown)";
 214         info_signal_strength = -1;
 215
 216         network.status += (status) => {
 217             stderr.printf("NETWORK STATUS\n");
 218             dump_table(status);
 219             acquire_new_status(status);
 220         };
 221
 222         network.signal_strength += (strength) => {
 223             stderr.printf("SIGNAL STRENGTH %d\n", strength);
 224             acquire_new_signal_strength(strength);
 225         };
 226
 227         call.call_status += on_call_status;
 228     }
 229
 230     /// Request GPS resource
 231     public override void start()
 232     {
 233         if (started) return;
 234
 235         status_changed("Starting");
 236
 237         script_start();
 238
 239         base.start();
 240     }
 241
 242     protected void on_name_owner_changed(DBus.Object sender, string name, string oldOwner, string newOwner)
 243     {
 244         zavai.log.debug("NOC " + name + " from " + oldOwner + " to " + newOwner);
 245         if (name == "org.freesmartphone.ogsmd" && newOwner != "")
 246         {
 247             status_changed("ogpsd came online");
 248             start_gsm.begin();
 249         }
 250     }
 251
 252     // Release usage of GPS
 253     public override void stop()
 254     {
 255         if (!started) return;
 256
 257         script_stop();
 258
 259         status_changed("");
 260         info_provider = "";
 261         info_signal_strength = -1;
 262         info_changed();
 263     }
 264
 265     protected override void cleanup_after_script_stop()
 266     {
 267         call = null;
 268     }
 269
 270     public async void start_gsm()
 271     {
 272         status_changed("Turning on antenna");
 273         while (true)
 274         {
 275             try {
 276                 yield device.set_antenna_power(true);
 277                 break;
 278             } catch (Error e) {
 279                 zavai.log.warning("SetAntennaPower: " + e.message);
 280                 if (e.message.str("current status is 'enabling'") != null
 281                  || e.message.str("current status is 'unknown'") != null)
 282                 {
 283                     status_changed("Waiting for ogsmd to settle");
 284                     zavai.log.info("trying again after 2 seconds");
 285                     Timeout.add(2 * 1000, () => {
 286                         start_gsm.callback();
 287                         return false;
 288                     });
 289                     yield;
 290                 } else {
 291                     status_changed("Checking if PIN is required");
 292                     string status = yield sim.get_auth_status();
 293                     zavai.log.info("on_auth_status: " + status);
 294                     if (status == "READY")
 295                         status_changed("PIN ok");
 296                     else if (status == "SIM PIN")
 297                     {
 298                         status_changed("Sending PIN");
 299                         yield sim.send_auth_code(zavai.config.sim_pin);
 300                         status_changed("PIN OK");
 301                     }
 302                     else
 303                         zavai.log.debug("Unknown status: " + status);
 304                 }
 305             }
 306         }
 307         zavai.log.warning("on_antenna_power ok");
 308         status_changed("Registering with network");
 309         yield network.register_();
 310         status_changed("Registered with network");
 311
 312         acquire_new_status(yield network.get_status());
 313         acquire_new_signal_strength(yield network.get_signal_strength());
 314     }
 315
 316     protected CallInfo? lookup_call(int gsm_id)
 317     {
 318         for (weak List<CallInfo> i = calls; i != null; i = i.next)
 319             if (i.data.gsm_id == gsm_id)
 320                 return i.data;
 321         return null;
 322     }
 323
 324     public void on_call_status(int index, string status, HashTable<string, Value?> properties)
 325     {
 326         stderr.printf("CALL STATUS %d %s\n", index, status);
 327         dump_table(properties);
 328
 329         CallInfo? info = lookup_call(index);
 330         if (info == null)
 331         {
 332             Value? v = properties.lookup("peer");
 333             string title;
 334             if (v != null)
 335                 title = "%s call from %s".printf(status, v.get_string());
 336             else
 337                 title = "%s call".printf(status);
 338
 339             info = new CallInfo();
 340             info.gsm_id = index;
 341             info.log_id = zavai.log.log.start("call", title);
 342             calls.append(info);
 343         }
 344
 345         // Log a summary of all info
 346         string call_info = "status: %s\n".printf(status);
 347         properties.for_each((pk, pv) => {
 348             string k = (string)pk;
 349             Value? v = (Value?)pv;
 350             call_info = call_info + "%s: %s\n".printf(k, v == null ? "(null)" : v.strdup_contents());
 351         });
 352         zavai.log.log.add(info.log_id, call_info);
 353
 354         // Remove entry when it's the last possible status
 355         if (status == "release")
 356         {
 357             zavai.log.log.end(info.log_id);
 358             for (weak List<CallInfo> i = calls; i != null; i = i.next)
 359                 if (i.data.gsm_id == index)
 360                 {
 361                     calls.delete_link(i);
 362                     break;
 363                 }
 364         }
 365
 366         /*
 367         dbg("cbCallStatus %d, %s, %s" % (id, status, formatDict(properties)))
 368         self.status = status
 369         if status == "incoming":
 370             if "peer" in properties and properties["peer"] == "+358942832031":
 371                 self.gsm_call_iface.ReleaseAll()
 372                 os.system("kapula-debug-call-handler &")
 373             else:
 374                 os.system("alsactl restore -f /etc/alsa-scenarios/stereoout-maxvolume.state")
 375                 os.system("vibrator-start")
 376                 os.system("ringtone-start")
 377                 os.system("ledctrl --on-time 400 --off-time 200 gta02-aux:red");
 378         if status == "release":
 379             os.system("ringtone-stop")
 380             os.system("vibrator-stop")
 381             os.system("ledctrl --off gta02-aux:red");
 382         */
 383     }
 384 }
 385
 386 public class GPRS: zavai.Service
 387 {
 388     public dynamic DBus.Object device;
 389
 390     public GPRS()
 391     {
 392         Object(name: "gsm.gprs");
 393
 394         device = zavai.registry.sbus.get_object(
 395             "org.freesmartphone.ogsmd",
 396             "/org/freesmartphone/GSM/Device",
 397             "org.freesmartphone.GSM.PDP");
 398     }
 399
 400     /// Request GPS resource
 401     public override void start()
 402     {
 403         if (started) return;
 404         try {
 405             //gsm.request(name);
 406             device.ActivateContext(
 407                 zavai.config.gprs_apn,
 408                 zavai.config.gprs_user,
 409                 zavai.config.gprs_pass);
 410             zavai.log.info("Started GPRS");
 411             base.start();
 412         } catch (GLib.Error e) {
 413             zavai.log.error(e.message);
 414         }
 415         base.start();
 416     }
 417
 418     // Release usage of GPS
 419     public override void stop()
 420     {
 421         if (!started) return;
 422         try {
 423             //gsm.release(name);
 424             device.DeactivateContext();
 425             zavai.log.info("Stopped GPRS");
 426             base.stop();
 427         } catch (GLib.Error e) {
 428             zavai.log.error(e.message);
 429         }
 430         base.stop();
 431     }
 432 }
 433
 434 public zavai.gsm.GSM gsm = null;
 435 public zavai.gsm.GPRS gprs = null;
 436
 437 public void init()
 438 {
 439     gsm = new GSM();
 440     gprs = new GPRS();
 441 }
 442
 443 }
 444 }