src/gsm.vala

   1 /*
   2  * gsm - gsm resource for zavai
   3  *
   4  * Copyright (C) 2009--2010  Enrico Zini <enrico@enricozini.org>
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19  */
  20
  21 using GLib;
  22
  23 namespace zavai {
  24 namespace gsm {
  25
  26 [DBus (name = "org.freesmartphone.GSM.Device")]
  27 public interface FSO_GSM_Device : Object {
  28     public abstract async int test_int (int i, out int j) throws DBus.Error;
  29     public abstract async string test_string (string s, out string t) throws DBus.Error;
  30     public abstract async void set_sim_buffers_sms(bool sim_buffers_sms) throws DBus.Error;
  31     public abstract async void set_r_t_c() throws DBus.Error;
  32     public abstract async void cancel_command() throws DBus.Error;
  33     public abstract async void set_antenna_power(bool power) throws DBus.Error;
  34     public abstract async GLib.HashTable<string, GLib.Value?> get_info() throws DBus.Error;
  35     public abstract async void set_microphone_muted(bool muted) throws DBus.Error;
  36     public signal void keypad_event(string name, bool pressed);
  37     public abstract async int get_speaker_volume() throws DBus.Error;
  38     public abstract async int get_r_t_c() throws DBus.Error;
  39     public abstract async void set_speaker_volume(int modem_volume) throws DBus.Error;
  40     public abstract async GLib.HashTable<string, GLib.Value?> get_features() throws DBus.Error;
  41     public abstract async bool get_microphone_muted() throws DBus.Error;
  42     public abstract async bool get_antenna_power() throws DBus.Error;
  43     public abstract async void get_power_status(out string param0, out int param1) throws DBus.Error;
  44     public abstract async bool get_sim_buffers_sms() throws DBus.Error;
  45 }
  46
  47 [DBus (name = "org.freesmartphone.GSM.SIM")]
  48 public interface FSO_GSM_SIM : GLib.Object {
  49     //public abstract async SIMParam0Struct[] retrieve_phonebook(string category) throws DBus.Error;
  50     public abstract async void send_auth_code(string code) throws DBus.Error;
  51     public abstract async string get_issuer() throws DBus.Error;
  52     public abstract async void change_auth_code(string old_pin, string new_pin) throws DBus.Error;
  53     public signal void auth_status(string status);
  54     public abstract async string send_generic_sim_command(string command) throws DBus.Error;
  55     public abstract async string[] list_phonebooks() throws DBus.Error;
  56     public abstract async void set_service_center_number(string number) throws DBus.Error;
  57     public abstract async GLib.HashTable<string, string> get_provider_list() throws DBus.Error;
  58     //public abstract async SIMParam0Struct2[] get_home_zones() throws DBus.Error;
  59     public signal void ready_status(bool status);
  60     public abstract async void retrieve_entry(string category, int index, out string param0, out string param1) throws DBus.Error;
  61     public abstract async void delete_message(int index) throws DBus.Error;
  62     public abstract async void send_restricted_sim_command(int command, int fileid, int p1, int p2, int p3, string data, out int param0, out int param1, out string param2) throws DBus.Error;
  63     public abstract async GLib.HashTable<string, GLib.Value?> get_messagebook_info() throws DBus.Error;
  64     public abstract async bool get_sim_ready() throws DBus.Error;
  65     public abstract async GLib.HashTable<string, GLib.Value?> get_phonebook_info(string category) throws DBus.Error;
  66     public signal void memory_full();
  67     public abstract async GLib.HashTable<string, GLib.Value?> get_sim_info() throws DBus.Error;
  68     public abstract async void set_auth_code_required(bool required, string pin) throws DBus.Error;
  69     public abstract async string get_auth_status() throws DBus.Error;
  70     public abstract async void send_stored_message(int index, out int param0, out string param1) throws DBus.Error;
  71     public abstract async int store_message(string number, string contents, GLib.HashTable<string, GLib.Value?> properties) throws DBus.Error;
  72     public abstract async bool get_auth_code_required() throws DBus.Error;
  73     public signal void incoming_stored_message(int index);
  74     public abstract async void retrieve_message(int index, out string param0, out string param1, out string param2, out GLib.HashTable<string, GLib.Value?> param3) throws DBus.Error;
  75     public abstract async void store_entry(string category, int index, string name, string number) throws DBus.Error;
  76     public abstract async void unlock(string puk, string new_pin) throws DBus.Error;
  77     public abstract async string get_service_center_number() throws DBus.Error;
  78     //public abstract async SIMParam0Struct23[] retrieve_messagebook(string category) throws DBus.Error;
  79     public abstract async void delete_entry(string category, int index) throws DBus.Error;
  80 }
  81
  82 [DBus (name = "org.freesmartphone.GSM.Network")]
  83 public interface FSO_GSM_Network : GLib.Object {
  84     public signal void status(GLib.HashTable<string, GLib.Value?> status);
  85     public signal void signal_strength(int strength);
  86     //public abstract async NetworkParam0Struct[] list_providers() throws DBus.Error;
  87     public abstract async GLib.HashTable<string, GLib.Value?> get_call_forwarding(string reason) throws DBus.Error;
  88     public signal void time_zone_report(int timezone);
  89     public abstract async void unregister() throws DBus.Error;
  90     public abstract async void set_calling_identification(string status) throws DBus.Error;
  91     public abstract async void register_() throws DBus.Error;
  92     public abstract async void send_ussd_request(string request) throws DBus.Error;
  93     public abstract async void disable_call_forwarding(string reason, string class_) throws DBus.Error;
  94     public signal void incoming_ussd(string mode, string message_);
  95     public abstract async int get_signal_strength() throws DBus.Error;
  96     public abstract async void enable_call_forwarding(string reason, string class_, string number, int timeout) throws DBus.Error;
  97     public abstract async string get_calling_identification() throws DBus.Error;
  98     public abstract async void register_with_provider(string operator_code) throws DBus.Error;
  99     public signal void cipher_status(string gsm, string gprs);
 100     public abstract async GLib.HashTable<string, GLib.Value?> get_status() throws DBus.Error;
 101     public abstract async void get_country_code(out string param0, out string param1) throws DBus.Error;
 102 }
 103
 104 [DBus (name = "org.freesmartphone.GSM.Call")]
 105 public interface FSO_GSM_Call : GLib.Object {
 106     public abstract async void activate(int index) throws DBus.Error;
 107     public abstract async void emergency(string number) throws DBus.Error;
 108     public abstract async void hold_active() throws DBus.Error;
 109     public abstract async void release_held() throws DBus.Error;
 110     public abstract async void send_dtmf(string tones) throws DBus.Error;
 111     public abstract async void release_all() throws DBus.Error;
 112     public abstract async int initiate(string number, string type_) throws DBus.Error;
 113     // public abstract async CallParam0Struct[] list_calls() throws DBus.Error;
 114     public abstract async void transfer(string number) throws DBus.Error;
 115     public abstract async void release(int index) throws DBus.Error;
 116     public signal void call_status(int index, string status, GLib.HashTable<string, GLib.Value?> properties);
 117     public abstract async void activate_conference(int index) throws DBus.Error;
 118 }
 119
 120 public class GSM: zavai.ScriptMonitorService
 121 {
 122     protected dynamic DBus.Object dbus;
 123     public FSO_GSM_Device device;
 124     public FSO_GSM_Network network;
 125     public FSO_GSM_SIM sim;
 126     public FSO_GSM_Call call;
 127
 128     protected class CallInfo
 129     {
 130         public int gsm_id;
 131         public uint log_id;
 132     }
 133     protected List<CallInfo> calls;
 134
 135     public string info_provider;
 136     public string info_registration;
 137     public int info_signal_strength;
 138
 139     public signal void status_changed(string message);
 140     public signal void info_changed();
 141
 142     protected void dump_table(HashTable<string, Value?> vals)
 143     {
 144         vals.for_each((pk, pv) => {
 145             string k = (string)pk;
 146             Value? v = (Value?)pv;
 147             stderr.printf("K: %s V: %s\n", k, v == null ? "(null)" : v.strdup_contents());
 148         });
 149     }
 150
 151     protected void acquire_new_status(HashTable<string, Value?> status)
 152     {
 153         // NETWORK STATUS
 154         // K: provider V: "vodafone UK"
 155         // K: mode V: "automatic"
 156         // K: registration V: "roaming"
 157         // K: cid V: "157F"
 158         // K: lac V: "0031"
 159         // K: act V: "GSM"
 160         // K: code V: "23415"
 161         bool changed = false;
 162
 163         var vprovider = status.lookup("provider");
 164         if (vprovider != null)
 165         {
 166             if (info_provider != vprovider.get_string())
 167             {
 168                 info_provider = vprovider.get_string();
 169                 changed = true;
 170             }
 171         }
 172
 173         var vregistration = status.lookup("registration");
 174         if (vregistration != null)
 175         {
 176             if (info_registration != vregistration.get_string())
 177             {
 178                 info_registration = vregistration.get_string();
 179                 changed = true;
 180             }
 181         }
 182
 183         if (changed)
 184         {
 185 stderr.printf("NOTIFY CHANGED\n");
 186             info_changed();
 187         }
 188     }
 189
 190     protected void acquire_new_signal_strength(int strength)
 191     {
 192         if (info_signal_strength != strength)
 193         {
 194             info_signal_strength = strength;
 195 stderr.printf("ACQUIRE SIG %d\n", info_signal_strength);
 196             info_changed();
 197         }
 198     }
 199
 200     public GSM()
 201     {
 202         Object(name: "gsm");
 203
 204         calls = new List<CallInfo>();
 205
 206         device = (FSO_GSM_Device)zavai.registry.sbus.get_object(
 207                 "org.freesmartphone.ogsmd",
 208                 "/org/freesmartphone/GSM/Device",
 209                 "org.freesmartphone.GSM.Device");
 210         network = (FSO_GSM_Network)zavai.registry.sbus.get_object(
 211             "org.freesmartphone.ogsmd",
 212             "/org/freesmartphone/GSM/Device",
 213             "org.freesmartphone.GSM.Network");
 214         sim = (FSO_GSM_SIM)zavai.registry.sbus.get_object(
 215                 "org.freesmartphone.ogsmd",
 216                 "/org/freesmartphone/GSM/Device",
 217                 "org.freesmartphone.GSM.SIM");
 218         call = (FSO_GSM_Call)zavai.registry.sbus.get_object(
 219             "org.freesmartphone.ogsmd",
 220             "/org/freesmartphone/GSM/Device",
 221             "org.freesmartphone.GSM.Call");
 222         dbus = zavai.registry.sbus.get_object(
 223                 "org.freedesktop.DBus",
 224                 "/org/freedesktop/DBus",
 225                 "org.freedesktop.DBus");
 226         dbus.NameOwnerChanged += on_name_owner_changed;
 227
 228         info_provider = "(unknown)";
 229         info_signal_strength = -1;
 230
 231         network.status += (status) => {
 232             stderr.printf("NETWORK STATUS\n");
 233             dump_table(status);
 234             acquire_new_status(status);
 235         };
 236
 237         network.signal_strength += (strength) => {
 238             stderr.printf("SIGNAL STRENGTH %d\n", strength);
 239             acquire_new_signal_strength(strength);
 240         };
 241
 242         call.call_status += on_call_status;
 243     }
 244
 245     /// Request GPS resource
 246     public override void start()
 247     {
 248         if (started) return;
 249
 250         status_changed("Starting");
 251
 252         script_start();
 253
 254         base.start();
 255     }
 256
 257     protected void on_name_owner_changed(DBus.Object sender, string name, string oldOwner, string newOwner)
 258     {
 259         zavai.log.debug("NOC " + name + " from " + oldOwner + " to " + newOwner);
 260         if (name == "org.freesmartphone.ogsmd" && newOwner != "")
 261         {
 262             status_changed("ogpsd came online");
 263             start_gsm.begin();
 264         }
 265     }
 266
 267     // Release usage of GPS
 268     public override void stop()
 269     {
 270         if (!started) return;
 271
 272         script_stop();
 273
 274         status_changed("");
 275         info_provider = "";
 276         info_signal_strength = -1;
 277         info_changed();
 278     }
 279
 280     protected override void cleanup_after_script_stop()
 281     {
 282         call = null;
 283     }
 284
 285     public async void start_gsm()
 286     {
 287         status_changed("Turning on antenna");
 288         while (true)
 289         {
 290             try {
 291                 yield device.set_antenna_power(true);
 292                 break;
 293             } catch (Error e) {
 294                 zavai.log.warning("SetAntennaPower: " + e.message);
 295                 if (e.message.str("current status is 'enabling'") != null
 296                  || e.message.str("current status is 'unknown'") != null)
 297                 {
 298                     status_changed("Waiting for ogsmd to settle");
 299                     zavai.log.info("trying again after 2 seconds");
 300                     Timeout.add(2 * 1000, () => {
 301                         start_gsm.callback();
 302                         return false;
 303                     });
 304                     yield;
 305                 } else {
 306                     status_changed("Checking if PIN is required");
 307                     string status = yield sim.get_auth_status();
 308                     zavai.log.info("on_auth_status: " + status);
 309                     if (status == "READY")
 310                         status_changed("PIN ok");
 311                     else if (status == "SIM PIN")
 312                     {
 313                         status_changed("Sending PIN");
 314                         yield sim.send_auth_code(zavai.config.sim_pin);
 315                         status_changed("PIN OK");
 316                     }
 317                     else
 318                         zavai.log.debug("Unknown status: " + status);
 319                 }
 320             }
 321         }
 322         zavai.log.warning("on_antenna_power ok");
 323         status_changed("Registering with network");
 324         yield network.register_();
 325         status_changed("Registered with network");
 326
 327         acquire_new_status(yield network.get_status());
 328         acquire_new_signal_strength(yield network.get_signal_strength());
 329     }
 330
 331     protected CallInfo? lookup_call(int gsm_id)
 332     {
 333         for (weak List<CallInfo> i = calls; i != null; i = i.next)
 334             if (i.data.gsm_id == gsm_id)
 335                 return i.data;
 336         return null;
 337     }
 338
 339     public void on_call_status(int index, string status, HashTable<string, Value?> properties)
 340     {
 341         stderr.printf("CALL STATUS %d %s\n", index, status);
 342         dump_table(properties);
 343
 344         CallInfo? info = lookup_call(index);
 345         if (info == null)
 346         {
 347             Value? v = properties.lookup("peer");
 348             string title;
 349             if (v != null)
 350                 title = "%s call from %s".printf(status, v.get_string());
 351             else
 352                 title = "%s call".printf(status);
 353
 354             info = new CallInfo();
 355             info.gsm_id = index;
 356             info.log_id = zavai.log.log.start("call", title);
 357             calls.append(info);
 358         }
 359
 360         // Log a summary of all info
 361         string call_info = "status: %s\n".printf(status);
 362         properties.for_each((pk, pv) => {
 363             string k = (string)pk;
 364             Value? v = (Value?)pv;
 365             call_info = call_info + "%s: %s\n".printf(k, v == null ? "(null)" : v.strdup_contents());
 366         });
 367         zavai.log.log.add(info.log_id, call_info);
 368
 369         // Remove entry when it's the last possible status
 370         if (status == "release")
 371         {
 372             zavai.log.log.end(info.log_id);
 373             for (weak List<CallInfo> i = calls; i != null; i = i.next)
 374                 if (i.data.gsm_id == index)
 375                 {
 376                     calls.delete_link(i);
 377                     break;
 378                 }
 379         }
 380
 381         /*
 382         dbg("cbCallStatus %d, %s, %s" % (id, status, formatDict(properties)))
 383         self.status = status
 384         if status == "incoming":
 385             if "peer" in properties and properties["peer"] == "+358942832031":
 386                 self.gsm_call_iface.ReleaseAll()
 387                 os.system("kapula-debug-call-handler &")
 388             else:
 389                 os.system("alsactl restore -f /etc/alsa-scenarios/stereoout-maxvolume.state")
 390                 os.system("vibrator-start")
 391                 os.system("ringtone-start")
 392                 os.system("ledctrl --on-time 400 --off-time 200 gta02-aux:red");
 393         if status == "release":
 394             os.system("ringtone-stop")
 395             os.system("vibrator-stop")
 396             os.system("ledctrl --off gta02-aux:red");
 397         */
 398     }
 399 }
 400
 401 public class GPRS: zavai.Service
 402 {
 403     public dynamic DBus.Object device;
 404
 405     public GPRS()
 406     {
 407         Object(name: "gsm.gprs");
 408
 409         device = zavai.registry.sbus.get_object(
 410             "org.freesmartphone.ogsmd",
 411             "/org/freesmartphone/GSM/Device",
 412             "org.freesmartphone.GSM.PDP");
 413     }
 414
 415     /// Request GPS resource
 416     public override void start()
 417     {
 418         if (started) return;
 419         try {
 420             //gsm.request(name);
 421             device.ActivateContext(
 422                 zavai.config.gprs_apn,
 423                 zavai.config.gprs_user,
 424                 zavai.config.gprs_pass);
 425             zavai.log.info("Started GPRS");
 426             base.start();
 427         } catch (GLib.Error e) {
 428             zavai.log.error(e.message);
 429         }
 430         base.start();
 431     }
 432
 433     // Release usage of GPS
 434     public override void stop()
 435     {
 436         if (!started) return;
 437         try {
 438             //gsm.release(name);
 439             device.DeactivateContext();
 440             zavai.log.info("Stopped GPRS");
 441             base.stop();
 442         } catch (GLib.Error e) {
 443             zavai.log.error(e.message);
 444         }
 445         base.stop();
 446     }
 447 }
 448
 449 public zavai.gsm.GSM gsm = null;
 450 public zavai.gsm.GPRS gprs = null;
 451
 452 public void init()
 453 {
 454     gsm = new GSM();
 455     gprs = new GPRS();
 456 }
 457
 458 }
 459 }